[arch-commits] Commit in haskell-monad-memo/repos (2 files)

[Felix Yan]

    Date: Thursday, April 22, 2021 @ 19:52:01
  Author: felixonmars
Revision: 921587

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-monad-memo/repos/community-staging-x86_64/
  haskell-monad-memo/repos/community-staging-x86_64/PKGBUILD
    (from rev 921586, haskell-monad-memo/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: haskell-monad-memo/repos/community-staging-x86_64/PKGBUILD (from rev 921586, haskell-monad-memo/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-04-22 19:52:01 UTC (rev 921587)
@@ -0,0 +1,46 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=monad-memo
+pkgname=haskell-monad-memo
+pkgver=0.5.3
+pkgrel=59
+pkgdesc="Memoization monad transformer"
+url="https://github.com/EduardSergeev/monad-memo"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-primitive' 'haskell-vector')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-random' 'haskell-test-framework'
+             'haskell-test-framework-quickcheck2')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('16f8c46673ac2564cd7d4d7ce901c25ded61d72283a93985db24dc6736c60dbb')
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test --show-details=direct
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}