[arch-commits] Commit in deepin-session-shell/repos (2 files)

[Felix Yan]

    Date: Sunday, April 25, 2021 @ 11:09:22
  Author: felixonmars
Revision: 924136

archrelease: copy trunk to community-testing-x86_64

Added:
  deepin-session-shell/repos/community-testing-x86_64/
  deepin-session-shell/repos/community-testing-x86_64/PKGBUILD
    (from rev 924135, deepin-session-shell/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: deepin-session-shell/repos/community-testing-x86_64/PKGBUILD (from rev 924135, deepin-session-shell/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2021-04-25 11:09:22 UTC (rev 924136)
@@ -0,0 +1,42 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Josip Ponjavic <josipponjavic at gmail dot com>
+# Contributor: Xu Fasheng <fasheng.xu[AT]gmail.com>
+
+pkgname=deepin-session-shell
+pkgver=5.4.9
+pkgrel=1
+pkgdesc='Deepin desktop-environment - session-shell module'
+arch=('x86_64')
+url="https://github.com/linuxdeepin/dde-session-shell"
+license=('GPL3')
+# qt5-tools: for qdbus executable
+depends=('deepin-daemon' 'deepin-qt5integration' 'deepin-wallpapers' 'gsettings-qt' 'liblightdm-qt5'
+         'qt5-tools' 'startdde')
+makedepends=('cmake' 'gmock' 'gtest' 'ninja')
+conflicts=('deepin-session-ui<5')
+provides=('lightdm-deepin-greeter')
+groups=('deepin')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/linuxdeepin/dde-session-shell/archive/$pkgver.tar.gz")
+sha512sums=('ba06ad832ce79f6a6e55d0911aa18cd14fd0a88f82cf8153bca08b8af16fafc1cf21d5ce5d181fcf205ce237007ad0db883c485a7d6e3f19fcc75bca7ee1429d')
+
+prepare() {
+  cd dde-session-shell-$pkgver
+  # We don't have common-auth on Arch
+  sed -i 's/common-auth/system-login/' src/libdde-auth/authagent.cpp
+
+  # Weird upstream depends on dtkwidget 5.5 and 5.4 at the same time, while they don't really need 5.5
+  sed -i 's|5\.5||' CMakeLists.txt tests/dde-lock/CMakeLists.txt tests/lightdm-deepin-greeter/CMakeLists.txt
+}
+
+build() {
+  cd dde-session-shell-$pkgver
+  cmake . -GNinja -DCMAKE_INSTALL_PREFIX=/usr
+  ninja
+}
+
+package() {
+  cd dde-session-shell-$pkgver
+  DESTDIR="$pkgdir" ninja install
+
+  chmod +x "$pkgdir"/usr/bin/deepin-greeter
+}