[arch-commits] Commit in deepin-file-manager/repos (2 files)

[Felix Yan]

    Date: Sunday, April 25, 2021 @ 22:17:54
  Author: felixonmars
Revision: 924462

archrelease: copy trunk to community-testing-x86_64

Added:
  deepin-file-manager/repos/community-testing-x86_64/
  deepin-file-manager/repos/community-testing-x86_64/PKGBUILD
    (from rev 924461, deepin-file-manager/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: deepin-file-manager/repos/community-testing-x86_64/PKGBUILD (from rev 924461, deepin-file-manager/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2021-04-25 22:17:54 UTC (rev 924462)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Josip Ponjavic <josipponjavic at gmail dot com>
+# Contributor: Xu Fasheng <fasheng.xu[AT]gmail.com>
+
+pkgname=deepin-file-manager
+pkgver=5.2.8
+pkgrel=1
+epoch=1
+pkgdesc='Deepin File Manager'
+arch=('x86_64')
+url="https://github.com/linuxdeepin/dde-file-manager"
+license=('GPL3')
+# startdde: for com.deepin.SessionManager
+depends=('deepin-qt5integration' 'deepin-anything' 'disomaster' 'file' 'gio-qt' 'libmediainfo'
+         'lucene++' 'avfs' 'polkit-qt5' 'poppler' 'ffmpegthumbnailer' 'jemalloc' 'kcodecs'
+         'startdde' 'taglib' 'htmlcxx' 'libgsf' 'mimetic' 'boost-libs')
+makedepends=('boost' 'qt5-tools' 'deepin-dock' 'deepin-movie' 'deepin-gettext-tools')
+optdepends=('deepin-manual: for help menual'
+            'deepin-shortcut-viewer: for shortcut display'
+            'deepin-screensaver: for screensaver chooser'
+            'deepin-movie: for video preview'
+            'deepin-terminal: for opening in terminal'
+            'deepin-compressor: for compress/decompress')
+groups=('deepin')
+provides=('deepin-desktop')
+conflicts=('deepin-desktop')
+replaces=('deepin-desktop')
+source=("https://github.com/linuxdeepin/dde-file-manager/archive/$pkgver/$pkgname-$pkgver.tar.gz")
+sha512sums=('5405bfdb157df03bf722897ec9d84a6a60cadf492b19f369a1008d6ae878dec43c622f55fc29c76e6305ed237ab12780b8a363378bcb4c97db8c0343134b1e9b')
+
+prepare() {
+  cd dde-file-manager-$pkgver
+  sed -e 's|systembusconf.path = /etc/dbus-1/system.d|systembusconf.path = /usr/share/dbus-1/system.d|' \
+      -e 's|systemd_service.path = /lib/systemd/system|systemd_service.path = /usr/lib/systemd/system|' \
+      -i src/dde-file-manager-daemon/dde-file-manager-daemon.pro
+}
+
+build() {
+  cd dde-file-manager-$pkgver
+  qmake-qt5 PREFIX=/usr filemanager.pro
+  make
+}
+
+package() {
+  cd dde-file-manager-$pkgver
+  make INSTALL_ROOT="$pkgdir" install
+}