[arch-commits] Commit in iaito/repos (2 files)
Levente Polyak
anthraxx at archlinux.org
Mon Apr 26 23:12:34 UTC 2021
Date: Monday, April 26, 2021 @ 23:12:34
Author: anthraxx
Revision: 924641
archrelease: copy trunk to community-staging-x86_64
Added:
iaito/repos/community-staging-x86_64/
iaito/repos/community-staging-x86_64/PKGBUILD
(from rev 924640, iaito/trunk/PKGBUILD)
----------+
PKGBUILD | 61 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 61 insertions(+)
Copied: iaito/repos/community-staging-x86_64/PKGBUILD (from rev 924640, iaito/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2021-04-26 23:12:34 UTC (rev 924641)
@@ -0,0 +1,61 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Maintainer: Santiago Torres-Arias <santiago[at]archlinux[dot]org>
+# Contributor: Aaron McDaniel (mcd1992) <'aur' at the domain 'fgthou.se'>
+
+pkgname=iaito
+_gitcommit=aec953b014cdc64d5303bc27de9a9c4565d7e8db
+pkgver=5.2.1
+pkgrel=1
+pkgdesc='Qt and C++ GUI for radare2 reverse engineering framework'
+url='https://github.com/radareorg/iaito'
+arch=('x86_64')
+license=('GPL3')
+depends=('radare2' 'capstone' 'qt5-base' 'qt5-svg' 'qt5-webengine' 'icu' 'python' 'jupyter'
+ 'pyside2' 'python-shiboken2' 'graphviz' 'gcc-libs' 'syntax-highlighting')
+makedepends=('git' 'cmake' 'ninja' 'shiboken2' 'qt5-tools')
+optdepends=('r2ghidra: ghidra decompiler plugin')
+replaces=('r2cutter')
+source=("git+https://github.com/radareorg/iaito#commit=${_gitcommit}"
+ "git+https://github.com/radareorg/iaito-translations")
+sha512sums=('SKIP'
+ 'SKIP')
+b2sums=('SKIP'
+ 'SKIP')
+
+pkgver() {
+ cd iaito
+ git describe --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+ cd iaito
+ git config 'submodule.src/translations.url' "${srcdir}/iaito-translations"
+ git submodule update --init src/translations
+ sed 's|cutterbindings_python.h|iaitobindings_python.h|g' -i src/plugins/PluginManager.cpp
+ sed 's|SBK_CUTTERPLUGIN_IDX|SBK_IAITOPLUGIN_IDX|g' -i src/plugins/PluginManager.cpp
+}
+
+build() {
+ cd iaito/src
+ cmake -B build \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_BUILD_TYPE=None \
+ -DIAITO_ENABLE_PYTHON=ON \
+ -DIAITO_ENABLE_PYTHON_BINDINGS=ON \
+ -DIAITO_USE_BUNDLED_RADARE2=OFF \
+ -DIAITO_USE_ADDITIONAL_RADARE2_PATHS=OFF \
+ -DIAITO_ENABLE_CRASH_REPORTS=OFF \
+ -DIAITO_ENABLE_GRAPHVIZ=ON \
+ -Wno-dev \
+ -G Ninja
+ ninja -C build
+}
+
+package() {
+ cd iaito
+ DESTDIR="${pkgdir}" ninja -C src/build install
+ install -d "${pkgdir}/usr/share/doc/${pkgname}"
+ cp -a docs/* "${pkgdir}/usr/share/doc/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list