[arch-commits] Commit in gmic/repos (2 files)
Antonio Rojas
arojas at gemini.archlinux.org
Mon Aug 2 21:42:00 UTC 2021
Date: Monday, August 2, 2021 @ 21:42:00
Author: arojas
Revision: 993137
archrelease: copy trunk to community-testing-x86_64
Added:
gmic/repos/community-testing-x86_64/
gmic/repos/community-testing-x86_64/PKGBUILD
(from rev 993136, gmic/trunk/PKGBUILD)
----------+
PKGBUILD | 76 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 76 insertions(+)
Copied: gmic/repos/community-testing-x86_64/PKGBUILD (from rev 993136, gmic/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD (rev 0)
+++ community-testing-x86_64/PKGBUILD 2021-08-02 21:42:00 UTC (rev 993137)
@@ -0,0 +1,76 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Jan "heftig" Steffens <jan.steffens at gmail.com>
+# Contributor: farid <farid at archlinuc-br.org>
+# Contributor: Archie <Mymaud at gmail.com>
+
+pkgbase=gmic
+pkgname=(gmic gimp-plugin-gmic krita-plugin-gmic)
+pkgver=2.9.8
+pkgrel=2
+arch=(x86_64)
+url='https://gmic.eu/'
+license=(custom:CeCILL)
+makedepends=(cmake gimp qt5-base fftw openexr opencv eigen graphicsmagick qt5-tools)
+source=(https://gmic.eu/files/source/gmic_$pkgver.tar.gz)
+sha256sums=('18d6bbc731ae3b4da8a656ac189476793b111a9dd19f72db2312f074df7cdc82')
+
+build() {
+ cmake -B build -S gmic-$pkgver \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DENABLE_DYNAMIC_LINKING=ON \
+ -DBUILD_LIB_STATIC=OFF \
+ -DENABLE_OPENCV=ON
+ cmake --build build
+
+ export LDFLAGS="$LDFLAGS -L../build"
+ cmake -B build-qt -S gmic-$pkgver/gmic-qt \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DENABLE_DYNAMIC_LINKING=ON \
+ -DGMIC_PATH="$srcdir"/gmic-$pkgver/src \
+ -DGMIC_QT_HOST=none
+ cmake --build build-qt
+
+ cmake -B build-gimp -S gmic-$pkgver/gmic-qt \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DENABLE_DYNAMIC_LINKING=ON \
+ -DGMIC_PATH="$srcdir"/gmic-$pkgver/src \
+ -DGMIC_QT_HOST=gimp
+ cmake --build build-gimp
+
+ cmake -B build-krita -S gmic-$pkgver/gmic-qt \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DENABLE_DYNAMIC_LINKING=ON \
+ -DGMIC_PATH="$srcdir"/gmic-$pkgver/src \
+ -DGMIC_QT_HOST=krita
+ cmake --build build-krita
+}
+
+package_gmic() {
+ pkgdesc="GREYC's Magic Image Converter: image processing framework"
+ depends=(graphicsmagick opencv fftw)
+ optdepends=('qt5-base: for the Qt UI')
+
+ DESTDIR="$pkgdir" cmake --install build
+ install -Dm644 gmic-$pkgver/COPYING "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+
+ DESTDIR="$pkgdir" cmake --install build-qt
+
+ install -Dm644 gmic-$pkgver/resources/gmic_cluts.gmz -t "$pkgdir"/usr/share/gmic
+}
+
+package_gimp-plugin-gmic() {
+ pkgdesc="Gimp plugin for the G'MIC image processing framework"
+ depends=(gimp gmic qt5-base)
+
+ DESTDIR="$pkgdir" cmake --install build-gimp
+ install -Dm644 gmic-$pkgver/COPYING "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_krita-plugin-gmic() {
+ pkgdesc="Krita plugin for the G'MIC image processing framework"
+ depends=(krita gmic)
+
+ DESTDIR="$pkgdir" cmake --install build-krita
+ install -Dm644 gmic-$pkgver/COPYING "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
More information about the arch-commits
mailing list