[arch-commits] Commit in buildah/repos (2 files)

[George Rawlinson]

    Date: Tuesday, August 3, 2021 @ 01:25:40
  Author: grawlinson
Revision: 993252

archrelease: copy trunk to community-testing-x86_64

Added:
  buildah/repos/community-testing-x86_64/
  buildah/repos/community-testing-x86_64/PKGBUILD
    (from rev 993251, buildah/trunk/PKGBUILD)

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Copied: buildah/repos/community-testing-x86_64/PKGBUILD (from rev 993251, buildah/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2021-08-03 01:25:40 UTC (rev 993252)
@@ -0,0 +1,37 @@
+# Maintainer: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+# Maintainer: Morten Linderud <foxboron at archlinux.org>
+
+pkgname=buildah
+pkgver=1.22.0
+pkgrel=1
+pkgdesc="A tool which facilitates building OCI images"
+arch=(x86_64)
+url="https://github.com/containers/buildah"
+license=(Apache)
+depends=(crun skopeo slirp4netns)
+makedepends=(go git bash-bats btrfs-progs device-mapper gpgme libassuan
+             bzip2 go-md2man runc skopeo systemd)
+_commit=e6ea308d6de1724a0ead3e08517a5e365461b275 #refs/tags/v1.21.4
+source=(git+https://github.com/containers/buildah.git#commit=$_commit)
+md5sums=('SKIP')
+
+pkgver() {
+  cd buildah
+  git describe --tags | sed 's/^[vV]//;s/-/+/g'
+}
+
+build() {
+  cd $pkgname
+  export GOFLAGS="-buildmode=pie -trimpath"
+  export CGO_LDFLAGS="${LDFLAGS}"
+  export CGO_CFLAGS="${CFLAGS}"
+  export CGO_CPPFLAGS="${CPPFLAGS}"
+  export CGO_CXXFLAGS="${CXXFLAGS}"
+  make PREFIX=/usr BUILDTAGS="containers_image_ostree_stub seccomp"
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" PREFIX=usr install install.completions
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}