[arch-commits] Commit in level-zero/repos (2 files)
Bruno Pagani
archange at gemini.archlinux.org
Wed Aug 4 23:30:08 UTC 2021
Date: Wednesday, August 4, 2021 @ 23:30:08
Author: archange
Revision: 993790
archrelease: copy trunk to community-testing-x86_64
Added:
level-zero/repos/community-testing-x86_64/
level-zero/repos/community-testing-x86_64/PKGBUILD
(from rev 993789, level-zero/trunk/PKGBUILD)
----------+
PKGBUILD | 49 +++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 49 insertions(+)
Copied: level-zero/repos/community-testing-x86_64/PKGBUILD (from rev 993789, level-zero/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD (rev 0)
+++ community-testing-x86_64/PKGBUILD 2021-08-04 23:30:08 UTC (rev 993790)
@@ -0,0 +1,49 @@
+# Maintainer: Daniel Bermond <dbermond at archlinux.org>
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+pkgbase=level-zero
+pkgname=(level-zero-headers level-zero-loader)
+pkgver=1.4.1
+pkgrel=1
+pkgdesc="API for accessing low level interfaces in oneAPI platform devices"
+arch=(x86_64)
+url="https://spec.oneapi.com/versions/latest/elements/l0/source/index.html"
+license=(MIT)
+makedepends=(cmake opencl-headers)
+source=(https://github.com/oneapi-src/level-zero/archive/v${pkgver}/${pkgbase}-${pkgver}.tar.gz)
+sha256sums=('2878fa29cbf5cea677a00f6dde6eb42d147c98c8d2a99fefece284d85cd1476b')
+
+prepare() {
+ printf '%s\n' ${pkgver##*.} > ${pkgbase}-${pkgver}/VERSION_PATCH
+}
+
+build() {
+ cmake -B build -S ${pkgbase}-${pkgver} \
+ -DCMAKE_BUILD_TYPE=None \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -Wno-dev
+ make -C build
+}
+
+package_level-zero-headers() {
+ pkgdesc+=" (headers)"
+ #arch=(any) # Not supported for now, maybe later
+
+ make -C build DESTDIR="${pkgdir}" install
+ install -Dm644 ${pkgbase}-${pkgver}/LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}
+
+ # remove loader files
+ [ -d 'loader' ] && rm -rf loader
+ install -d -m755 loader
+ mv "${pkgdir}"/usr/lib loader
+}
+
+package_level-zero-loader() {
+ pkgdesc+=" (loader)"
+ depends=(gcc-libs)
+ optdepends=('level-zero-driver: for packaged Level Zero driver')
+
+ mv loader "${pkgdir}"/usr
+ install -Dm644 ${pkgbase}-${pkgver}/LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}
+
More information about the arch-commits
mailing list