[arch-commits] Commit in gpsd/repos (3 files)

[Antonio Rojas]

    Date: Saturday, August 7, 2021 @ 20:49:37
  Author: arojas
Revision: 994701

archrelease: copy trunk to community-staging-x86_64

Added:
  gpsd/repos/community-staging-x86_64/
  gpsd/repos/community-staging-x86_64/PKGBUILD
    (from rev 994700, gpsd/trunk/PKGBUILD)
  gpsd/repos/community-staging-x86_64/gpsd.conf
    (from rev 994700, gpsd/trunk/gpsd.conf)

-----------+
 PKGBUILD  |   65 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 gpsd.conf |    5 ++++
 2 files changed, 70 insertions(+)

Copied: gpsd/repos/community-staging-x86_64/PKGBUILD (from rev 994700, gpsd/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-08-07 20:49:37 UTC (rev 994701)
@@ -0,0 +1,65 @@
+# Maintainer: Jaroslav Lichtblau <svetlemodry at archlinux.org>
+# Contributor: Tom Gundersen <teg at jklm.no>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Giacomo Rizzo <alt at free-os.it>
+
+pkgname=gpsd
+pkgver=3.23
+pkgrel=1
+pkgdesc="GPS daemon and library to support USB/serial GPS devices"
+arch=('x86_64')
+url="http://catb.org/gpsd/"
+license=('BSD')
+depends=('python' 'libusb' 'bluez-libs' 'pps-tools')
+optdepends=('gtk3: GUI frontends'
+            'php: generate a PHP status page for your GPS'
+            'php-gd: image support for the PHP status page'
+            'python-cairo: GUI frontends'
+            'python-gobject: GUI frontends'
+            'python-pyserial: GUI frontends'
+            'qt5-base: for Qgpsmm')
+makedepends=('scons' 'docbook-xsl' 'qt5-base' 'python-gobject' 'python-cairo' 'python-pyserial' 'gtk3')
+backup=('etc/default/gpsd')
+source=(https://download-mirror.savannah.gnu.org/releases/$pkgname/$pkgname-$pkgver.tar.gz{,.sig}
+        $pkgname.conf)
+sha256sums=('522c2362a7eb2d7ac37eaa1504f12aded1c373479a87ba06cc6795974b567bbc'
+            'SKIP'
+            'dcfa71c4c730b486269995468bdcfa8e96bf3c282db1dadea9384d32015d277f')
+validpgpkeys=('EED4A0893DCC705DB309E202CCF29C7238522905') # Gary E. Miller <gem at rellim.com>
+# validpgpkeys=('41876B2F579463A499843D1DECC8208F8C6C738D') # Eric S. Raymond
+
+build() {
+  cd $pkgname-$pkgver
+
+  export LINKFLAGS="${LDFLAGS}"
+  _pythonpath=`python -c "from sysconfig import get_path; print(get_path('platlib'))"`
+  scons prefix=/usr \
+        systemd=yes \
+        gpsd_group=uucp \
+        python_libdir=$_pythonpath \
+        sbindir=/usr/bin \
+        qt_versioned=5
+  scons build
+}
+
+package() {
+  cd $pkgname-$pkgver
+
+  export DESTDIR="${pkgdir}"
+  scons install
+  install -Dm755 gpsinit -t "${pkgdir}"/usr/bin
+
+  install -Dm644 "$srcdir/gpsd.conf" "${pkgdir}"/etc/default/gpsd
+
+  install -Dm644 gpsd-$pkgver/gpsd.rules "${pkgdir}"/usr/lib/udev/rules.d/25-gpsd-usb.rules
+
+  install -Dm755 gpsd.hotplug -t "${pkgdir}"/usr/lib/udev/
+
+  install -Dm644 packaging/X11/*.desktop -t "${pkgdir}"/usr/share/applications/
+  install -Dm644 packaging/X11/gpsd-logo.png -t "${pkgdir}"/usr/share/gpsd/
+
+  install -Dm644 gpsd-$pkgver/systemd/{gpsd.service,gpsd.socket,gpsdctl at .service} -t "${pkgdir}"/usr/lib/systemd/system/
+
+  install -Dm644 COPYING "${pkgdir}"/usr/share/licenses/$pkgname/LICENSE
+}

Copied: gpsd/repos/community-staging-x86_64/gpsd.conf (from rev 994700, gpsd/trunk/gpsd.conf)
===================================================================
--- community-staging-x86_64/gpsd.conf	                        (rev 0)
+++ community-staging-x86_64/gpsd.conf	2021-08-07 20:49:37 UTC (rev 994701)
@@ -0,0 +1,5 @@
+# Default settings for gpsd.
+START_DAEMON="true"
+GPSD_OPTIONS=""
+DEVICES=""
+USBAUTO="true"