[arch-commits] Commit in ruby-ffi/repos (2 files)
George Rawlinson
grawlinson at gemini.archlinux.org
Tue Aug 10 02:37:38 UTC 2021
Date: Tuesday, August 10, 2021 @ 02:37:37
Author: grawlinson
Revision: 997304
archrelease: copy trunk to community-testing-x86_64
Added:
ruby-ffi/repos/community-testing-x86_64/
ruby-ffi/repos/community-testing-x86_64/PKGBUILD
(from rev 997303, ruby-ffi/trunk/PKGBUILD)
----------+
PKGBUILD | 49 +++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 49 insertions(+)
Copied: ruby-ffi/repos/community-testing-x86_64/PKGBUILD (from rev 997303, ruby-ffi/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD (rev 0)
+++ community-testing-x86_64/PKGBUILD 2021-08-10 02:37:37 UTC (rev 997304)
@@ -0,0 +1,49 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Contributor: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Mario Finelli <mario at finel dot li>
+# Contributor: Artem Vorotnikov <artem at vorotnikov dot me>
+
+_gemname=ffi
+pkgname=ruby-$_gemname
+pkgver=1.15.3
+pkgrel=1
+pkgdesc='Ruby FFI'
+arch=('x86_64')
+url='https://github.com/ffi/ffi'
+license=('BSD')
+depends=('ruby')
+makedepends=('ruby-rdoc')
+options=('!emptydirs')
+source=("https://rubygems.org/downloads/$_gemname-$pkgver.gem")
+noextract=("$_gemname-$pkgver.gem")
+sha512sums=('f7b8d6257d12a6572a847eb17b117ee61c547500c11b73c097f95471975360311174d9d0d42865e2b6c54ee05d595aa3c90ea63563972db71e4ac6bb5e4aae79')
+
+package() {
+ local _gemdir="$(ruby -e'puts Gem.default_dir')"
+
+ gem install \
+ --verbose \
+ --ignore-dependencies \
+ --no-user-install \
+ --install-dir "$pkgdir/$_gemdir" \
+ --bindir "$pkgdir/usr/bin" \
+ "$_gemname-$pkgver.gem"
+
+ # delete unnecessary files & folders
+ cd "$pkgdir/$_gemdir"
+ find . -type f \
+ -name "page-Makefile.ri" -delete \
+ -o -name 'gem_make.out' -delete \
+ -o -name 'mkmf.log' -delete
+ rm -vrf cache
+ cd "gems/$_gemname-$pkgver"
+ rm -vrf ext rakelib "$_gemname.gemspec" Gemfile Rakefile
+
+ # move documentation
+ install -vd "$pkgdir/usr/share/doc/$pkgname"
+ mv -v samples CHANGELOG.md README.md "$pkgdir/usr/share/doc/$pkgname"
+
+ # move licenses
+ install -vd "$pkgdir/usr/share/licenses/$pkgname"
+ mv -v LICENSE* COPYING "$pkgdir/usr/share/licenses/$pkgname"
+}
More information about the arch-commits
mailing list