[arch-commits] Commit in akonadi/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Antonio Rojas]

    Date: Thursday, August 12, 2021 @ 09:18:20
  Author: arojas
Revision: 421382

archrelease: copy trunk to testing-x86_64

Added:
  akonadi/repos/testing-x86_64/
  akonadi/repos/testing-x86_64/PKGBUILD
    (from rev 421381, akonadi/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: akonadi/repos/testing-x86_64/PKGBUILD (from rev 421381, akonadi/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2021-08-12 09:18:20 UTC (rev 421382)
@@ -0,0 +1,42 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Pierre Schmitz <pierre at archlinux.de>
+
+pkgbase=akonadi
+pkgname=(akonadi libakonadi)
+pkgver=21.08.0
+pkgrel=1
+pkgdesc='PIM layer, which provides an asynchronous API to access all kind of PIM data'
+arch=(x86_64)
+url='https://kontact.kde.org'
+license=(LGPL)
+makedepends=(extra-cmake-modules postgresql qt5-tools boost kitemmodels kaccounts-integration)
+source=(https://download.kde.org/stable/release-service/$pkgver/src/$pkgname-$pkgver.tar.xz{,.sig})
+sha256sums=('7a697427e198fcef19718a73f0c4459467e2a3bdc880f63ab46de41802464f62'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87  # Christoph Feck <cfeck at kde.org>
+              D81C0CB38EB725EF6691C385BB463350D6EF31EF) # Heiko Becker <heiko.becker at kde.org>
+
+build() {
+  cmake -B build -S $pkgname-$pkgver \
+    -DBUILD_TESTING=OFF
+  cmake --build build
+}
+
+package_libakonadi() {
+  pkgdesc='Libraries used by applications based on Akonadi'
+  depends=(kitemmodels kaccounts-integration)
+
+  DESTDIR="$pkgdir" cmake --install build
+  rm -r "$pkgdir"/usr/bin # Provided by akonadi
+}
+
+package_akonadi() {
+  depends=(libakonadi mariadb)
+  optdepends=('postgresql: PostgreSQL backend')
+
+  DESTDIR="$pkgdir" cmake --install build
+  rm -r "$pkgdir"/{etc,usr/{include,lib,share}} # Provided by libakonadi
+}