[arch-commits] Commit in (4 files)

[George Rawlinson]

    Date: Friday, August 13, 2021 @ 07:10:58
  Author: grawlinson
Revision: 997931

addpkg: cargo-sort 1.0.5-2

Added:
  cargo-sort/
  cargo-sort/repos/
  cargo-sort/trunk/
  cargo-sort/trunk/PKGBUILD

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Added: cargo-sort/trunk/PKGBUILD
===================================================================
--- cargo-sort/trunk/PKGBUILD	                        (rev 0)
+++ cargo-sort/trunk/PKGBUILD	2021-08-13 07:10:58 UTC (rev 997931)
@@ -0,0 +1,44 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Contributor: Dominic Meiser [git at msrd0 dot de]
+
+pkgname=cargo-sort
+pkgver=1.0.5
+pkgrel=2
+pkgdesc="Check if tables and items in a .toml file are lexically sorted"
+arch=('x86_64')
+url="https://github.com/DevinR528/cargo-sort"
+license=('Apache' 'MIT')
+makedepends=('rust' 'llvm' 'clang')
+source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
+b2sums=('647ecaea8e6b5a1f53460996b1374a502c4d0356a29d982c67ee83682710e74a7f709c2495291c1be70e572e77176cbbe29fc7d1728ab88283d586bf948ff40b')
+
+prepare() {
+  cd "$pkgname-$pkgver"
+  cargo fetch --locked
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  cargo build --release --frozen
+}
+
+check() {
+  cd "$pkgname-$pkgver"
+  cargo test --frozen
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+
+  # binary
+  install -vDm755 -t "$pkgdir/usr/bin" "target/release/$pkgname"
+
+  # licenses
+  install -vd "$pkgdir/usr/share/licenses/$pkgname"
+  sed -n '/^####.*$/,/^<\/sub>$/p' README.md \
+    > "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+
+  # documentation
+  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
+  cp -vr examp "$pkgdir/usr/share/doc/$pkgname/examples"
+}