[arch-commits] Commit in haskell-hls-fourmolu-plugin/repos (2 files)

[Felix Yan]

    Date: Friday, August 13, 2021 @ 19:21:04
  Author: felixonmars
Revision: 998321

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hls-fourmolu-plugin/repos/community-staging-x86_64/
  haskell-hls-fourmolu-plugin/repos/community-staging-x86_64/PKGBUILD
    (from rev 998320, haskell-hls-fourmolu-plugin/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: haskell-hls-fourmolu-plugin/repos/community-staging-x86_64/PKGBUILD (from rev 998320, haskell-hls-fourmolu-plugin/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-08-13 19:21:04 UTC (rev 998321)
@@ -0,0 +1,53 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=hls-fourmolu-plugin
+pkgname=haskell-hls-fourmolu-plugin
+pkgver=1.0.0.1
+pkgrel=28
+pkgdesc="Integration with the Fourmolu code formatter"
+url="https://hackage.haskell.org/package/hls-fourmolu-plugin"
+license=("Apache")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-fourmolu' 'haskell-ghc' 'haskell-ghcide' 'haskell-hls-plugin-api'
+         'haskell-lens' 'haskell-lsp' 'haskell-ghc-api-compat')
+makedepends=('ghc' 'uusi' 'haskell-hls-test-utils' 'haskell-lsp-test')
+checkdepends=('git')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('c78f938155ba487d550e4afb11363c5aded34d5592a74680eb73a022ffda3b0d')
+
+prepare() {
+  cd $_hkgname-$pkgver
+  gen-setup
+  uusi -r ghc:ghc,ghc-api-compat $_hkgname.cabal
+}
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test --show-details=direct
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}