[arch-commits] Commit in openmw/repos (2 files)

[Sven-Hendrik Haase]

    Date: Monday, August 16, 2021 @ 08:40:54
  Author: svenstaro
Revision: 1000183

archrelease: copy trunk to community-testing-x86_64

Added:
  openmw/repos/community-testing-x86_64/
  openmw/repos/community-testing-x86_64/PKGBUILD
    (from rev 1000182, openmw/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: openmw/repos/community-testing-x86_64/PKGBUILD (from rev 1000182, openmw/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2021-08-16 08:40:54 UTC (rev 1000183)
@@ -0,0 +1,39 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at gmail.com>
+# Contributor: Sandy Carter <bwrsandman at gmail.com>
+
+pkgname=openmw
+# Build from git until 0.47.0 stable is out. Sadly openmw releases are very
+# rare these days and backporting takes too much time.
+pkgver=0.47.0rc
+pkgrel=1
+pkgdesc="Open-source engine reimplementation for the role-playing game Morrowind"
+arch=('x86_64')
+url="http://www.openmw.org"
+license=('GPL3' 'MIT' 'custom')
+depends=('openal' 'openscenegraph' 'mygui' 'qt5-base' 'ffmpeg' 'sdl2' 'unshield' 'libxt')
+makedepends=('cmake' 'boost' 'doxygen' 'ninja' 'git')
+source=("git+https://gitlab.com/OpenMW/openmw.git#commit=af3b9187")
+sha512sums=('SKIP')
+
+build() {
+  cd openmw
+  # We can't use system bullet because openmw needs a version built with double
+  # precision but the one we ship in Arch is built with single precision for
+  # performance reasons.
+  cmake \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DOPENMW_LTO_BUILD=ON \
+    -DDESIRED_QT_VERSION=5 \
+    -DOPENMW_USE_SYSTEM_BULLET=OFF \
+    -GNinja \
+    -Bbuild
+  ninja -C build
+}
+
+package() {
+  cd openmw
+  DESTDIR="$pkgdir" ninja -C build install
+}
+
+# vim: ts=2 sw=2 et: