[arch-commits] Commit in libsrtp/repos/extra-x86_64 (PKGBUILD PKGBUILD)

[Jan Steffens]

    Date: Monday, August 16, 2021 @ 17:11:17
  Author: heftig
Revision: 422288

archrelease: copy trunk to extra-x86_64

Added:
  libsrtp/repos/extra-x86_64/PKGBUILD
    (from rev 422287, libsrtp/trunk/PKGBUILD)
Deleted:
  libsrtp/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |  106 +++++++++++++++++++++++++++++++------------------------------
 1 file changed, 54 insertions(+), 52 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2021-08-16 17:11:09 UTC (rev 422287)
+++ PKGBUILD	2021-08-16 17:11:17 UTC (rev 422288)
@@ -1,52 +0,0 @@
-# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
-# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
-# Contributor: Yejun Yang <yejunx AT gmail DOT com>
-# Contributor: Michal Krenek <mikos at sg1.cz>
-
-pkgname=libsrtp
-pkgver=2.3.0
-pkgrel=1
-epoch=1
-pkgdesc="Library for SRTP (Secure Realtime Transport Protocol)"
-url="https://github.com/cisco/libsrtp"
-arch=(x86_64)
-license=(BSD)
-depends=(openssl)
-makedepends=(git)
-checkdepends=(libpcap procps-ng)
-options=(staticlibs)
-_commit=d02d21111e379c297e93a9033d7b653135f732ee  # tags/v2.3.0
-source=("git+https://github.com/cisco/libsrtp#commit=$_commit")
-sha256sums=('SKIP')
-
-pkgver() {
-  cd $pkgname
-  git describe --tags | sed 's/^v//;s/-/+/g'
-}
-
-prepare() {
-  cd $pkgname
-
-  # Fixup pkgver: There are tags like v1.5.4 but also "moving" tags like v1 and v1.5
-  git tag | grep -Pv '^v\d+.\d+.\d+$' | xargs git tag -d
-
-  autoreconf -fvi
-}
-
-build() {
-  cd $pkgname
-  ./configure --prefix=/usr --enable-openssl
-  make all
-  make shared_library  # Keep separate to link test apps against static lib
-}
-
-check() {
-  cd $pkgname
-  make runtest
-}
-
-package() {
-  cd $pkgname
-  make DESTDIR="$pkgdir" install
-  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 LICENSE
-}

Copied: libsrtp/repos/extra-x86_64/PKGBUILD (from rev 422287, libsrtp/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2021-08-16 17:11:17 UTC (rev 422288)
@@ -0,0 +1,54 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Yejun Yang <yejunx AT gmail DOT com>
+# Contributor: Michal Krenek <mikos at sg1.cz>
+
+pkgname=libsrtp
+pkgver=2.4.0
+pkgrel=1
+epoch=1
+pkgdesc="Library for SRTP (Secure Realtime Transport Protocol)"
+url="https://github.com/cisco/libsrtp"
+arch=(x86_64)
+license=(BSD)
+depends=(nss)
+makedepends=(git meson libpcap doxygen)
+checkdepends=(procps-ng)
+provides=("libsrtp${pkgver%%.*}.so")
+_commit=063e3652feae15ec48614a91d32757781e6251b4  # tags/v2.4.0
+source=("git+https://github.com/cisco/libsrtp#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  # Fixup pkgver: There are tags like v1.5.4 but also "moving" tags like v1 and v1.5
+  git tag | grep -Pv '^v\d+.\d+.\d+$' | xargs git tag -d
+}
+
+build() {
+  arch-meson $pkgname build \
+    --buildtype release \
+    -D crypto-library=nss \
+    -D crypto-library-kdf=disabled
+  meson compile -C build
+  meson compile -C build doc
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  meson install -C build --destdir "$pkgdir"
+
+  mkdir -p "$pkgdir/usr/share/doc"
+  cp -a build/html "$pkgdir/usr/share/doc/$pkgname"
+
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $pkgname/LICENSE
+}