[arch-commits] Commit in go/repos (2 files)

[Morten Linderud]

    Date: Monday, August 16, 2021 @ 21:20:21
  Author: foxboron
Revision: 1001086

archrelease: copy trunk to community-testing-x86_64

Added:
  go/repos/community-testing-x86_64/
  go/repos/community-testing-x86_64/PKGBUILD
    (from rev 1001085, go/trunk/PKGBUILD)

----------+
 PKGBUILD |   87 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 87 insertions(+)

Copied: go/repos/community-testing-x86_64/PKGBUILD (from rev 1001085, go/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2021-08-16 21:20:21 UTC (rev 1001086)
@@ -0,0 +1,87 @@
+# Maintainer: Morten Linderud <foxboron at archlinux.org>
+# Contributor: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+# Contributor: Alexander F. Rødseth <xyproto at archlinux.org>
+# Contributor: Pierre Neidhardt <ambrevar at gmail.com>
+# Contributor: Vesa Kaihlavirta <vegai at iki.fi>
+# Contributor: Rémy Oudompheng <remy at archlinux.org>
+# Contributor: Andres Perera <andres87p gmail>
+# Contributor: Matthew Bauer <mjbauer95 at gmail.com>
+# Contributor: Christian Himpel <chressie at gmail.com>
+# Contributor: Mike Rosset <mike.rosset at gmail.com>
+# Contributor: Daniel YC Lin <dlin.tw at gmail.com>
+# Contributor: John Luebs <jkluebs at gmail.com>
+
+pkgname=go
+epoch=2
+pkgver=1.17
+pkgrel=1
+pkgdesc='Core compiler tools for the Go programming language'
+arch=(x86_64)
+url='https://golang.org/'
+license=(BSD)
+makedepends=(git go perl)
+replaces=(go-pie)
+provides=(go-pie)
+options=(!strip staticlibs)
+source=(https://storage.googleapis.com/golang/go$pkgver.src.tar.gz{,.asc})
+validpgpkeys=('EB4C1BFD4F042F6DDDCCEC917721F63BD38B4796')
+sha256sums=('3a70e5055509f347c0fb831ca07a2bf3b531068f349b14a3c652e9b5b67beb5d'
+            'SKIP')
+
+build() {
+  export GOARCH=amd64
+  export GOROOT_FINAL=/usr/lib/go
+  export GOROOT_BOOTSTRAP=/usr/lib/go
+  export GOPATH="$srcdir/"
+  export GOROOT="$srcdir/$pkgname"
+  export GOBIN="$GOROOT/bin"
+
+  cd "$pkgname/src"
+  ./make.bash --no-clean -v
+
+  PATH="$GOBIN:$PATH" go install -v std
+}
+
+check() {
+  export GOARCH=amd64
+  export GOROOT_FINAL=/usr/lib/go
+  export GOROOT_BOOTSTRAP=/usr/lib/go
+  export GOROOT="$srcdir/$pkgname"
+  export GOBIN="$GOROOT/bin"
+  export PATH="$srcdir/$pkgname/bin:$PATH"
+  export GO_TEST_TIMEOUT_SCALE=3
+
+  cd $pkgname/src
+  ./run.bash --no-rebuild -v -v -v -k
+}
+
+package() {
+  cd "$pkgname"
+
+  install -d "$pkgdir/usr/bin" "$pkgdir/usr/lib/go" "$pkgdir/usr/share/doc/go" \
+    "$pkgdir/usr/lib/go/pkg/linux_amd64_"{dynlink,race}
+
+  # TODO: Make split package for source files?
+  # This saves around 100 MB.
+  # Rest of the size is from the duplicate _race and _dynlib .a files
+  # cp -a bin pkg src lib misc api test "$pkgdir/usr/lib/go"
+  cp -a bin pkg src lib "$pkgdir/usr/lib/go"
+  cp -r doc/* "$pkgdir/usr/share/doc/go"
+
+  ln -sf /usr/lib/go/bin/go "$pkgdir/usr/bin/go"
+  ln -sf /usr/lib/go/bin/gofmt "$pkgdir/usr/bin/gofmt"
+  ln -sf /usr/share/doc/go "$pkgdir/usr/lib/go/doc"
+
+  install -Dm644 VERSION "$pkgdir/usr/lib/go/VERSION"
+
+  rm -rf "$pkgdir/usr/lib/go/pkg/bootstrap" "$pkgdir/usr/lib/go/pkg/tool/*/api"
+
+  # TODO: Figure out if really needed
+  rm -rf "$pkgdir"/usr/lib/go/pkg/obj/go-build/*
+  find "$pkgdir/usr/lib/go" -name "testdata" -type d -prune -exec rm -rf "{}" \;
+  find "$pkgdir/usr/lib/go" -name "*_test.go" -exec rm -rf "{}" \;
+
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+# vim: ts=2 sw=2 et