[arch-commits] Commit in python-pylint/trunk (PKGBUILD)

[Caleb Maclennan]

    Date: Friday, August 20, 2021 @ 14:09:16
  Author: alerque
Revision: 1003990

upgpkg: python-pylint 2.9.6-1

Modified:
  python-pylint/trunk/PKGBUILD

----------+
 PKGBUILD |   63 ++++++++++++++++++++++++++++++++++---------------------------
 1 file changed, 36 insertions(+), 27 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2021-08-20 14:04:27 UTC (rev 1003989)
+++ PKGBUILD	2021-08-20 14:09:16 UTC (rev 1003990)
@@ -1,41 +1,50 @@
-# Maintainer: Angel Velasquez <angvp at archlinux.org>
-# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Angel Velasquez <angvp at archlinux.org>
+# Contributor: Felix Yan <felixonmars at archlinux.org>
 # Contributor: Stéphane Gaudreault <stephane at archlinux.org>
 # Contributor: Alexander Fehr <pizzapunk gmail com>
 
-pkgname=python-pylint
-pkgver=2.8.2
+_pyname=pylint
+pkgname=python-$_pyname
+pkgver=2.9.6
 pkgrel=1
-pkgdesc="Analyzes Python code looking for bugs and signs of poor quality"
-arch=('any')
-url="https://pylint.org"
-license=('GPL')
-depends=('python-astroid' 'python-mccabe' 'python-isort' 'python-setuptools' 'python-toml')
-makedepends=('python-pytest-runner' 'python-pytest-benchmark' 'python-setuptools-scm'
-             'python-sphinx')
-checkdepends=('mpdecimal')
-optdepends=('tk: Pylint GUI'
-            'graphviz: To have other output formats than dot or vcg')
+pkgdesc='Analyzes Python code looking for bugs and signs of poor quality'
+arch=(any)
+url=https://pylint.org
+license=(GPL)
+_pydeps=(appdirs
+         astroid
+         isort
+         mccabe
+         toml)
+depends=(python
+         "${_pydeps[@]/#/python-}")
+makedepends=(python-setuptools
+             python-sphinx)
+checkdepends=(mpdecimal
+              python-pytest)
+optdepends=('graphviz: Enable output formats other than dot or vcg'
+            'tk: Pylint GUI')
+_archive="$_pyname-$pkgver"
 source=("https://github.com/PyCQA/pylint/archive/v$pkgver/pylint-$pkgver.tar.gz")
-sha512sums=('7023603668f540ecc0b35f3289377855c4c0df01e04a9af255f5c8031f568f6b76508bb3a7f0aba8e76a86b63eae423908c30f47258d6dee46bb23320c952701')
+sha256sums=('e6335c810ee3ff4b59e3990db49cf0d1e263e122b766853755436d88133c9496')
 
-export SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver
-
 build() {
-  cd pylint-$pkgver
-  python setup.py build
-  make PYTHONPATH="$PWD/build/lib" -C doc man
+	cd "$_archive"
+	python setup.py build
+	make PYTHONPATH="$PWD/build/lib" -C doc man
 }
 
 check() {
-  cd pylint-$pkgver
-  python setup.py pytest || echo "Tests failed"
+	cd "$_archive"
+	PYTHONPATH="$PWD/build/lib" pytest \
+		--deselect tests/benchmark/test_baseline_benchmarks.py \
+		--deselect tests/test_functional.py::test_functional[arguments_renamed]
 }
 
 package() {
-  cd pylint-$pkgver
-  python setup.py install --prefix=/usr --root="$pkgdir" --skip-build --optimize=1
-
-  install -d "$pkgdir"/usr/share/man/man1
-  install -m644 doc/_build/man/* "$pkgdir"/usr/share/man/man1
+	cd "$_archive"
+	export PYTHONHASHSEED=0
+	python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+	install -Dm0644 -t "$pkgdir/usr/share/man/man1/" doc/_build/man/*
 }