[arch-commits] Commit in python-pylint/repos (2 files)
Caleb Maclennan
alerque at gemini.archlinux.org
Fri Aug 20 14:10:03 UTC 2021
Date: Friday, August 20, 2021 @ 14:10:03
Author: alerque
Revision: 1003991
archrelease: copy trunk to community-testing-any
Added:
python-pylint/repos/community-testing-any/
python-pylint/repos/community-testing-any/PKGBUILD
(from rev 1003990, python-pylint/trunk/PKGBUILD)
----------+
PKGBUILD | 50 ++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 50 insertions(+)
Copied: python-pylint/repos/community-testing-any/PKGBUILD (from rev 1003990, python-pylint/trunk/PKGBUILD)
===================================================================
--- community-testing-any/PKGBUILD (rev 0)
+++ community-testing-any/PKGBUILD 2021-08-20 14:10:03 UTC (rev 1003991)
@@ -0,0 +1,50 @@
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Angel Velasquez <angvp at archlinux.org>
+# Contributor: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Stéphane Gaudreault <stephane at archlinux.org>
+# Contributor: Alexander Fehr <pizzapunk gmail com>
+
+_pyname=pylint
+pkgname=python-$_pyname
+pkgver=2.9.6
+pkgrel=1
+pkgdesc='Analyzes Python code looking for bugs and signs of poor quality'
+arch=(any)
+url=https://pylint.org
+license=(GPL)
+_pydeps=(appdirs
+ astroid
+ isort
+ mccabe
+ toml)
+depends=(python
+ "${_pydeps[@]/#/python-}")
+makedepends=(python-setuptools
+ python-sphinx)
+checkdepends=(mpdecimal
+ python-pytest)
+optdepends=('graphviz: Enable output formats other than dot or vcg'
+ 'tk: Pylint GUI')
+_archive="$_pyname-$pkgver"
+source=("https://github.com/PyCQA/pylint/archive/v$pkgver/pylint-$pkgver.tar.gz")
+sha256sums=('e6335c810ee3ff4b59e3990db49cf0d1e263e122b766853755436d88133c9496')
+
+build() {
+ cd "$_archive"
+ python setup.py build
+ make PYTHONPATH="$PWD/build/lib" -C doc man
+}
+
+check() {
+ cd "$_archive"
+ PYTHONPATH="$PWD/build/lib" pytest \
+ --deselect tests/benchmark/test_baseline_benchmarks.py \
+ --deselect tests/test_functional.py::test_functional[arguments_renamed]
+}
+
+package() {
+ cd "$_archive"
+ export PYTHONHASHSEED=0
+ python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+ install -Dm0644 -t "$pkgdir/usr/share/man/man1/" doc/_build/man/*
+}
More information about the arch-commits
mailing list