[arch-commits] Commit in perl-shell-command/repos (2 files)
Caleb Maclennan
alerque at gemini.archlinux.org
Fri Aug 20 15:39:40 UTC 2021
Date: Friday, August 20, 2021 @ 15:39:40
Author: alerque
Revision: 1004003
archrelease: copy trunk to community-any
Added:
perl-shell-command/repos/community-any/
perl-shell-command/repos/community-any/PKGBUILD
(from rev 1004002, perl-shell-command/trunk/PKGBUILD)
----------+
PKGBUILD | 37 +++++++++++++++++++++++++++++++++++++
1 file changed, 37 insertions(+)
Copied: perl-shell-command/repos/community-any/PKGBUILD (from rev 1004002, perl-shell-command/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD (rev 0)
+++ community-any/PKGBUILD 2021-08-20 15:39:40 UTC (rev 1004003)
@@ -0,0 +1,37 @@
+# Maintainer: Caleb Maclennan< caleb at alerque.com>
+# Contributor: Anton Leontiev <scileont at gmail.com>
+
+_cpan=Shell-Command
+pkgname=perl-${_cpan,,}
+pkgver=0.06
+pkgrel=3
+pkgdesc='Perl module providing cross-platform functions emulating common shell commands'
+arch=(any)
+url="https://metacpan.org/release/$_cpan"
+license=(GPL PerlArtistic)
+depends=(perl)
+options=(!emptydirs)
+_archive="$_cpan-$pkgver"
+source=("https://cpan.perl.org/modules/by-module/${_cpan%-*}/$_archive.tar.gz")
+sha256sums=('f3e4deef577944be46fa7af5ac118ac2828911788b01bc76a74495355616ecd1')
+
+build() {
+ cd "$_archive"
+ unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
+ export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
+ perl Makefile.PL
+ make
+}
+
+check() {
+ cd "$_archive"
+ unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
+ export PERL_MM_USE_DEFAULT=1
+ make test
+}
+
+package() {
+ cd "$_archive"
+ unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
+ make install INSTALLDIRS=vendor DESTDIR="$pkgdir"
+}
More information about the arch-commits
mailing list