[arch-commits] Commit in (myrepos myrepos/repos myrepos/trunk myrepos/trunk/PKGBUILD)

[Caleb Maclennan]

    Date: Friday, August 20, 2021 @ 17:18:21
  Author: alerque
Revision: 1004011

initial: myrepos 1.20180726-6

Added:
  myrepos/
  myrepos/repos/
  myrepos/trunk/
  myrepos/trunk/PKGBUILD

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Added: myrepos/trunk/PKGBUILD
===================================================================
--- myrepos/trunk/PKGBUILD	                        (rev 0)
+++ myrepos/trunk/PKGBUILD	2021-08-20 17:18:21 UTC (rev 1004011)
@@ -0,0 +1,52 @@
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Joshua Haase <hahj87 at gmail.com>
+# Contributor: Matjaž Mozetič (https://github.com/sysadminmatmoz)
+# Contributor: Vincent Demeester <vincent at sbr.pm>
+# Contributor: Nicolas Pouillard (http://nicolaspouillard.fr)
+# Contributor: Peter Simons <simons at cryp.to>
+# Contributor: Andreas Hilboll <andreas at hilboll.de>
+# Contributor: <kljohann at gmail.com>
+# Contributor: Andy Weidenbaum <archbaum at gmail.com>
+
+pkgname=myrepos
+pkgver=1.20180726
+pkgrel=6
+pkgdesc='Multiple Repository management tool'
+arch=(any)
+url=https://myrepos.branchable.com
+license=(GPL2)
+depends=(perl)
+optdepends=('bzr: support for bzr repositories'
+            'cvs: support for cvs repositories'
+            'darcs: support for darcs repositories'
+            'git-annex: support for git-annex clones'
+            'git: support for git repositories'
+            'mercurial: support for mercurial repositories'
+            'perl-html-parser: support for webcheckout'
+            'perl-libwww: support for webcheckout'
+            'perl-uri: support for webcheckout heuristically guessing partial URLs'
+            'repo: support for repo repositories'
+            'svn: support for subversion repositories'
+            'unison: support for unison as a vcs'
+            'vcsh: support for vcsh')
+provides=(mr
+          webcheckout)
+_archive="$pkgname-$pkgver"
+source=("https://git.joeyh.name/index.cgi/myrepos.git/snapshot/$_archive.tar.gz")
+sha256sums=('bfb909037da678a1668f3f7f86efee7ee31f2bc66d90b83dd9e6b6a5f998c4e2')
+
+build() {
+	cd "$_archive"
+	make
+}
+
+check() {
+	cd "$_archive"
+	make test
+}
+
+package() {
+	cd "$_archive"
+	make DESTDIR="$pkgdir" install
+	install -Dm0644 -t "$pkgdir/usr/share/doc/$pkgname/" README
+}