[arch-commits] Commit in haskell-doctemplates/repos (2 files)

Felix Yan felixonmars at gemini.archlinux.org
Thu Aug 26 10:57:14 UTC 2021


    Date: Thursday, August 26, 2021 @ 10:57:14
  Author: felixonmars
Revision: 1005932

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-doctemplates/repos/community-staging-x86_64/
  haskell-doctemplates/repos/community-staging-x86_64/PKGBUILD
    (from rev 1005931, haskell-doctemplates/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-doctemplates/repos/community-staging-x86_64/PKGBUILD (from rev 1005931, haskell-doctemplates/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-08-26 10:57:14 UTC (rev 1005932)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=doctemplates
+pkgname=haskell-doctemplates
+pkgver=0.10
+pkgrel=9
+pkgdesc="Pandoc-style document templates"
+url="https://github.com/jgm/doctemplates"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-doclayout' 'haskell-hsyaml' 'haskell-safe'
+         'haskell-scientific' 'haskell-text-conversions' 'haskell-unordered-containers'
+         'haskell-vector')
+makedepends=('ghc' 'haskell-glob' 'haskell-tasty' 'haskell-tasty-golden' 'haskell-tasty-hunit'
+             'haskell-temporary')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('3b974314f2bcd3edf269ab89d2edb7dbf2e4e052ff0c098ebb6c2eb5b77a839639860c9de45259cb92eb0e35a9ce56ed865efe7597e61a1326e3091eae726a57')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir="$pkgname" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}



More information about the arch-commits mailing list