[arch-commits] Commit in elvish/repos/community-x86_64 (4 files)

[George Rawlinson]

    Date: Saturday, August 28, 2021 @ 18:08:17
  Author: grawlinson
Revision: 1007797

archrelease: copy trunk to community-x86_64

Added:
  elvish/repos/community-x86_64/PKGBUILD
    (from rev 1007796, elvish/trunk/PKGBUILD)
  elvish/repos/community-x86_64/elvish.install
    (from rev 1007796, elvish/trunk/elvish.install)
Deleted:
  elvish/repos/community-x86_64/PKGBUILD
  elvish/repos/community-x86_64/elvish.install

----------------+
 PKGBUILD       |  126 +++++++++++++++++++++++++++----------------------------
 elvish.install |   28 ++++++------
 2 files changed, 77 insertions(+), 77 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2021-08-28 18:07:16 UTC (rev 1007796)
+++ PKGBUILD	2021-08-28 18:08:17 UTC (rev 1007797)
@@ -1,63 +0,0 @@
-# Maintainer: George Rawlinson <grawlinson at archlinux.org>
-# Contributor: Haochen Tong <i at hexchain dot org>
-# Contributor: Qi Xiao <xiaqqaix at gmail dot com>
-
-pkgname=elvish
-pkgver=0.16.2
-pkgrel=1
-pkgdesc="A friendly and expressive Unix shell"
-arch=('x86_64')
-url="https://elv.sh"
-license=('BSD')
-makedepends=('git' 'go')
-install="$pkgname.install"
-source=("$pkgname-$pkgver.tar.gz::https://github.com/elves/elvish/archive/v$pkgver.tar.gz")
-b2sums=('d76942353dc46c8ee8a04c585c745b2c4ba39857bfca8738d24e186ae88e83a57633190d55d138cca2459e265e2125ba588496908da9e2fcd20b0ff9069d194f')
-
-prepare() {
-  cd "$pkgname-$pkgver"
-
-  # create directory for build output
-  mkdir build
-
-  # download dependencies
-  go mod vendor
-}
-
-build() {
-  cd "$pkgname-$pkgver"
-
-  # set Go flags
-  export CGO_CPPFLAGS="${CPPFLAGS}"
-  export CGO_CFLAGS="${CFLAGS}"
-  export CGO_CXXFLAGS="${CXXFLAGS}"
-
-  go build -v \
-    -trimpath \
-    -buildmode=pie \
-    -mod=vendor \
-    -modcacherw \
-    -ldflags "-linkmode external -extldflags ${LDFLAGS} \
-    -X github.com/elves/elvish/pkg/buildinfo.Reproducible=true \
-    -X github.com/elves/elvish/pkg/buildinfo.Version=$pkgver" \
-    -o build \
-    ./cmd/...
-}
-
-check() {
-  cd "$pkgname-$pkgver"
-  go test -v -race ./...
-}
-
-package() {
-  cd "$pkgname-$pkgver"
-
-  # binary
-  install -vDm755 -t "$pkgdir/usr/bin" build/elvish
-
-  # documentation
-  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" ./*.md
-
-  # license
-  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
-}

Copied: elvish/repos/community-x86_64/PKGBUILD (from rev 1007796, elvish/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2021-08-28 18:08:17 UTC (rev 1007797)
@@ -0,0 +1,63 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Contributor: Haochen Tong <i at hexchain dot org>
+# Contributor: Qi Xiao <xiaqqaix at gmail dot com>
+
+pkgname=elvish
+pkgver=0.16.3
+pkgrel=1
+pkgdesc="A friendly and expressive Unix shell"
+arch=('x86_64')
+url="https://elv.sh"
+license=('BSD')
+makedepends=('git' 'go')
+install="$pkgname.install"
+source=("$pkgname-$pkgver.tar.gz::https://github.com/elves/elvish/archive/v$pkgver.tar.gz")
+b2sums=('e6e412cad068e01bf9d8d0d5709a3463e12bad782b2b0efe8c2b2810d349eae407de68a8b9226e4481e3f51b116207f884342b115e316b42eeb916d1c63bfdd7')
+
+prepare() {
+  cd "$pkgname-$pkgver"
+
+  # create directory for build output
+  mkdir build
+
+  # download dependencies
+  go mod vendor
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+
+  # set Go flags
+  export CGO_CPPFLAGS="${CPPFLAGS}"
+  export CGO_CFLAGS="${CFLAGS}"
+  export CGO_CXXFLAGS="${CXXFLAGS}"
+
+  go build -v \
+    -trimpath \
+    -buildmode=pie \
+    -mod=vendor \
+    -modcacherw \
+    -ldflags "-linkmode external -extldflags ${LDFLAGS} \
+    -X github.com/elves/elvish/pkg/buildinfo.Reproducible=true \
+    -X github.com/elves/elvish/pkg/buildinfo.Version=$pkgver" \
+    -o build \
+    ./cmd/...
+}
+
+check() {
+  cd "$pkgname-$pkgver"
+  go test -v -race ./...
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+
+  # binary
+  install -vDm755 -t "$pkgdir/usr/bin" build/elvish
+
+  # documentation
+  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" ./*.md
+
+  # license
+  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
+}

Deleted: elvish.install
===================================================================
--- elvish.install	2021-08-28 18:07:16 UTC (rev 1007796)
+++ elvish.install	2021-08-28 18:08:17 UTC (rev 1007797)
@@ -1,14 +0,0 @@
-post_install() {
-  grep -Fqx /bin/elvish /etc/shells || echo /bin/elvish >> /etc/shells
-  grep -Fqx /usr/bin/elvish /etc/shells || echo /usr/bin/elvish >> /etc/shells
-}
-
-post_upgrade() {
-  post_install
-}
-
-pre_remove() {
-  sed -i -r '/^(\/usr)?\/bin\/elvish$/d' etc/shells
-}
-
-# vim:set ts=2 sw=2 et:

Copied: elvish/repos/community-x86_64/elvish.install (from rev 1007796, elvish/trunk/elvish.install)
===================================================================
--- elvish.install	                        (rev 0)
+++ elvish.install	2021-08-28 18:08:17 UTC (rev 1007797)
@@ -0,0 +1,14 @@
+post_install() {
+  grep -Fqx /bin/elvish /etc/shells || echo /bin/elvish >> /etc/shells
+  grep -Fqx /usr/bin/elvish /etc/shells || echo /usr/bin/elvish >> /etc/shells
+}
+
+post_upgrade() {
+  post_install
+}
+
+pre_remove() {
+  sed -i -r '/^(\/usr)?\/bin\/elvish$/d' etc/shells
+}
+
+# vim:set ts=2 sw=2 et: