[arch-commits] Commit in python-faker/repos (2 files)

[Felix Yan]

    Date: Wednesday, December 1, 2021 @ 11:37:32
  Author: felixonmars
Revision: 1059230

archrelease: copy trunk to community-staging-any

Added:
  python-faker/repos/community-staging-any/
  python-faker/repos/community-staging-any/PKGBUILD
    (from rev 1059228, python-faker/trunk/PKGBUILD)

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Copied: python-faker/repos/community-staging-any/PKGBUILD (from rev 1059228, python-faker/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2021-12-01 11:37:32 UTC (rev 1059230)
@@ -0,0 +1,41 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Jeremy "Ichimonji10" Audet <ichimonji10 at gmail dot com>
+# Contributor: dnuux <dnuuxx at gmail.com>
+
+pkgname=python-faker
+pkgver=8.14.2
+pkgrel=2
+pkgdesc='Faker generates fake data for you.'
+arch=('any')
+url='https://faker.readthedocs.io/en/master/'
+license=('MIT')
+provides=("python-fake-factory=$pkgver")
+conflicts=('python-fake-factory')
+replaces=('python-fake-factory')
+depends=('python-setuptools' 'python-dateutil' 'python-text-unidecode')
+makedepends=('python-pip' 'python-wheel' 'python-pytest-runner')
+checkdepends=('python-validators' 'python-ukpostcodeparser' 'python-random2'
+              'python-freezegun' 'python-pillow')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/joke2k/faker/archive/v$pkgver.tar.gz")
+sha512sums=('764067eb28e490a2fc601bff97ac403aa568e24aa30284153d21f0affc769fbbabe14a451647b1d6474230cec292dbe3a014f149a05291586ddd40d71cc6aa5d')
+
+prepare() {
+  sed -i -e 's/==/>=/' faker-$pkgver/setup.py
+}
+
+build() {
+  cd faker-$pkgver
+  python setup.py build
+}
+
+check() {
+  cd faker-$pkgver
+  python setup.py egg_info
+  python -m pytest
+}
+
+package() {
+  cd faker-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -Dm 644 LICENSE.txt "$pkgdir"/usr/share/licenses/${pkgname}/LICENSE.txt
+}