[arch-commits] Commit in python-httpcore/repos (2 files)

[Felix Yan]

    Date: Wednesday, December 1, 2021 @ 13:49:45
  Author: felixonmars
Revision: 1059274

archrelease: copy trunk to community-staging-any

Added:
  python-httpcore/repos/community-staging-any/
  python-httpcore/repos/community-staging-any/PKGBUILD
    (from rev 1059273, python-httpcore/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: python-httpcore/repos/community-staging-any/PKGBUILD (from rev 1059273, python-httpcore/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2021-12-01 13:49:45 UTC (rev 1059274)
@@ -0,0 +1,45 @@
+# Maintainer: Eli Schwartz <eschwartz at archlinux.org>
+
+_pkgname=httpcore
+pkgname=python-httpcore
+pkgver=0.14.3
+pkgrel=2
+pkgdesc="A minimal HTTP client"
+arch=('any')
+url="https://github.com/encode/${_pkgname}"
+license=('BSD')
+depends=('python-anyio' 'python-h11' 'python-sniffio' 'python-certifi')
+optdepends=('python-h2: for HTTP/2 support')
+makedepends=('python-setuptools' 'python-h2')
+checkdepends=('hypercorn' 'python-curio' 'python-pproxy' 'python-pytest-asyncio' 'python-pytest-httpbin' 'python-pytest-trio' 'python-trustme' 'uvicorn')
+source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/${pkgver}.tar.gz")
+sha512sums=('05e92109839c2e2f7ec81fea9507fb15a12d1bf6ae92048170953b1cb0139237b81c892feff1bc3840e06887e8916cadcc4124725874344524e45e3640a00379')
+
+prepare() {
+    cd ${_pkgname}-${pkgver}
+
+    # do not run coverage in unittests!
+    sed -i '/^addopts/d' setup.cfg
+}
+
+build() {
+    cd ${_pkgname}-${pkgver}
+
+    python setup.py build
+}
+
+check() {
+    cd ${_pkgname}-${pkgver}
+
+    # raise open files limits, many tests will fail otherwise
+    ulimit -S -n 4096
+
+    python -m pytest
+}
+
+package() {
+    cd ${_pkgname}-${pkgver}
+
+    python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+    install -Dm644 LICENSE.md "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE.md
+}