[arch-commits] Commit in python-django-rest-framework/repos (2 files)

[Felix Yan]

    Date: Wednesday, December 1, 2021 @ 14:48:07
  Author: felixonmars
Revision: 1059318

archrelease: copy trunk to community-staging-any

Added:
  python-django-rest-framework/repos/community-staging-any/
  python-django-rest-framework/repos/community-staging-any/PKGBUILD
    (from rev 1059317, python-django-rest-framework/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: python-django-rest-framework/repos/community-staging-any/PKGBUILD (from rev 1059317, python-django-rest-framework/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2021-12-01 14:48:07 UTC (rev 1059318)
@@ -0,0 +1,53 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+_name=django-rest-framework
+pkgname=python-django-rest-framework
+pkgver=3.12.4
+pkgrel=2
+pkgdesc="A powerful and flexible toolkit for building Web APIs."
+arch=('any')
+url="https://www.django-rest-framework.org/"
+license=('BSD')
+depends=('python-django')
+makedepends=('python-setuptools')
+checkdepends=('python-pytest' 'python-pytest-django')
+# bootstrap without python-django-filter, as it has a checkdepends on
+# python-django-rest-framework
+optdepends=('python-django-filter: for dynamic queryset filters'
+            'python-django-guardian: for a per-object permission model'
+            'python-markdown: for markdown support'
+            'python-psycopg2: for PostgreSQL support'
+            'python-pygments: for syntax highlighting'
+            'python-yaml: for YAML support')
+# tests are not complete in pypi sdist:
+# https://github.com/encode/django-rest-framework/issues/7141
+source=("${pkgname}-${pkgver}.tar.gz::https://github.com/encode/${_name}/archive/${pkgver}.tar.gz")
+sha512sums=('406b5354809b94e371a2c7d4b62ce66c18a1f60bd02574cba603ad4c44faa4297bdbbd6ee50de63fe21d2aae18386e05d46983a506bddd17f06ce610d5b727c9')
+b2sums=('48150e8d966ddd169a2b58d90656efa8f9f549c9d2fdee6025254fba2a6221704fe6bcb246567c8acb963f76ea56046935d3190c7c391daf4773b100a641ba02')
+
+prepare() {
+  mv -v "${_name}-${pkgver}" "$pkgname-$pkgver"
+  cd "$pkgname-$pkgver"
+  # we do not use coverage during testing
+  sed -e '/addopts/d' -i setup.cfg
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  python setup.py build
+}
+
+check() {
+  cd "$pkgname-$pkgver"
+  export PYTHONPATH="${PWD}/build:${PYTHONPATH}"
+  pytest -v
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  python setup.py install --skip-build \
+    --optimize=1 \
+    --root="${pkgdir}"
+  install -vDm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -vDm 644 LICENSE.md -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}