[arch-commits] Commit in python-pytest-helpers-namespace/repos (2 files)

[Evangelos Foutras]

    Date: Wednesday, December 1, 2021 @ 14:48:40
  Author: foutrelis
Revision: 1059338

archrelease: copy trunk to community-staging-any

Added:
  python-pytest-helpers-namespace/repos/community-staging-any/
  python-pytest-helpers-namespace/repos/community-staging-any/PKGBUILD
    (from rev 1059337, python-pytest-helpers-namespace/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: python-pytest-helpers-namespace/repos/community-staging-any/PKGBUILD (from rev 1059337, python-pytest-helpers-namespace/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2021-12-01 14:48:40 UTC (rev 1059338)
@@ -0,0 +1,47 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+_name=pytest-helpers-namespace
+pkgname=python-pytest-helpers-namespace
+pkgver=2021.4.29
+pkgrel=2
+pkgdesc="PyTest Helpers Namespace"
+arch=('any')
+url="https://github.com/saltstack/pytest-helpers-namespace"
+license=('Apache')
+depends=('python-pytest')
+makedepends=('git' 'python-setuptools-declarative-requirements' 'python-setuptools-scm' 'python-toml')
+checkdepends=('python-pytest')
+source=("git+https://github.com/saltstack/pytest-helpers-namespace#tag=v${pkgver}?signed")
+sha512sums=('SKIP')
+validpgpkeys=('D2908FB3A823B0FAB3BD21F5BB36BF6584A298FF') # Pedro Algarvio (s0undt3ch) <pedro at algarvio.me>
+
+prepare() {
+  mv -v "${_name}" "$pkgname-$pkgver"
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  python setup.py build
+}
+
+check() {
+  cd "$pkgname-$pkgver"
+  # installing into test location, so pytest can pick up the extension
+  mkdir -vp test_dir
+  python setup.py install --skip-build \
+    --optimize=1 \
+    --root="test_dir"
+
+  local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
+  export PYTHONPATH="test_dir/${site_packages}:${PYTHONPATH}"
+  # only use working test: https://github.com/saltstack/pytest-helpers-namespace/issues/10
+  pytest -vv -k 'test_helper_contains_method'
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  python setup.py install --skip-build \
+    --optimize=1 \
+    --root="${pkgdir}"
+  install -vDm 644 {AUTHORS,README}.rst -t "${pkgdir}/usr/share/doc/${pkgname}"
+}