[arch-commits] Commit in weechat/repos (2 files)

[Felix Yan]

    Date: Wednesday, December 1, 2021 @ 14:50:47
  Author: felixonmars
Revision: 1059393

archrelease: copy trunk to community-staging-x86_64

Added:
  weechat/repos/community-staging-x86_64/
  weechat/repos/community-staging-x86_64/PKGBUILD
    (from rev 1059391, weechat/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: weechat/repos/community-staging-x86_64/PKGBUILD (from rev 1059391, weechat/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-12-01 14:50:47 UTC (rev 1059393)
@@ -0,0 +1,49 @@
+# Maintainer : Christian Rebischke <Chris.Rebischke at archlinux.org>
+# Maintainer : Eli Schwartz <eschwartz at archlinux.org>
+# Contributor: Giovanni Scafora <giovanni at archlinux.org>
+# Contributor: lucke <lucke at o2 dot pl>
+
+pkgname=weechat
+pkgver=3.3
+pkgrel=2
+pkgdesc="Fast, light and extensible IRC client (curses UI)"
+arch=('x86_64')
+url="https://www.weechat.org/"
+license=('GPL')
+depends=('gnutls' 'curl' 'libgcrypt')
+makedepends=('asciidoctor' 'cmake' 'aspell' 'guile' 'lua' 'perl' 'python'
+             'ruby' 'tcl')
+optdepends=('aspell: spellchecker support'
+            'guile: support for guile scripts'
+            'lua: support for lua scripts'
+            'perl: support for perl scripts'
+            'python: support for python scripts'
+            'ruby: support for ruby scripts'
+            'tcl: support for tcl scripts')
+source=("https://www.weechat.org/files/src/${pkgname}-${pkgver}.tar.xz"{,.asc})
+sha512sums=('18bbaa93620185ead64f64833e4c5df6a1cbc49dc6f60362614e955947221b78baaa93a2748f153bbb6f7867c7760f7a8fa8d6d9ed30040ad5e12af127526e13'
+            'SKIP')
+b2sums=('9cb119c2506ff5f9b4844b8016790af34347e300a1217762afc1307191cd0831c2c23e019a024c8161ff2e46607eddf94f94b3db9bd351bc51b7f057ddb375eb'
+        'SKIP')
+validpgpkeys=('A9AB5AB778FA5C3522FD0378F82F4B16DEC408F8') # WeeChat (signing key) <webmaster at weechat.org>
+
+# cmake does not correctly handle CPPFLAGS, so kludge it in anyway:
+# https://gitlab.kitware.com/cmake/cmake/-/issues/12928
+CFLAGS+=" ${CPPFLAGS}"
+
+build() {
+  mkdir -p build
+  cd build
+  cmake -Wno-dev "${srcdir}/${pkgname}-${pkgver}" \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DENABLE_MAN=ON \
+        -DENABLE_DOC=ON \
+        -DENABLE_JAVASCRIPT=OFF \
+        -DENABLE_PHP=OFF
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="${pkgdir}" install
+}