[arch-commits] Commit in python-pyscreenshot/repos (2 files)

[Felix Yan]

    Date: Wednesday, December 1, 2021 @ 14:52:22
  Author: felixonmars
Revision: 1059439

archrelease: copy trunk to community-staging-any

Added:
  python-pyscreenshot/repos/community-staging-any/
  python-pyscreenshot/repos/community-staging-any/PKGBUILD
    (from rev 1059438, python-pyscreenshot/trunk/PKGBUILD)

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Copied: python-pyscreenshot/repos/community-staging-any/PKGBUILD (from rev 1059438, python-pyscreenshot/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2021-12-01 14:52:22 UTC (rev 1059439)
@@ -0,0 +1,41 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+_pkg=pyscreenshot
+pkgname=python-${_pkg}
+pkgver=3.0
+pkgrel=2
+pkgdesc="Copy the contents of the screen to a PIL or Pillow image memory"
+arch=(any)
+url="https://github.com/ponty/pyscreenshot"
+license=(BSD)
+depends=(python-easyprocess python-entrypoint2 python-mss python-jeepney)
+makedepends=(python-setuptools)
+checkdepends=(
+    python-pytest python-pyvirtualdisplay python-pillow python-path.py
+    python-xlib python-gobject python-pyqt5 python-wxpython pyside2
+    xorg-server-xvfb xorg-xdpyinfo gnome-screenshot scrot imagemagick
+    maim pqiv
+)
+source=(https://files.pythonhosted.org/packages/source/${_pkg::1}/${_pkg}/${_pkg}-${pkgver}.tar.gz)
+#source=(${url}/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha256sums=('dd4fdfaeb617483913a6b16845b9f428de5db28758979f4b6cf8f236d292b908')
+
+build() {
+  cd ${_pkg}-${pkgver}
+  python setup.py build
+}
+
+check() {
+  cd ${_pkg}-${pkgver}
+  export PYTHONPATH="${PWD}/build/lib/" 
+  python -m pyscreenshot.check.versions
+#  python -m pyscreenshot.check.speedtest --virtual-display
+  xvfb-run -n 101 -s "+extension RANDR -br -screen 0 900x800x24" python -m pytest -v
+  xvfb-run -n 102 -s "-extension RANDR -br -screen 0 900x800x24" python -m pytest -v
+}
+
+package() {
+  cd ${_pkg}-${pkgver}
+  python setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=1
+  install -Dm644 LICENSE.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}