[arch-commits] Commit in python-matrix-nio/repos (2 files)

[Felix Yan]

    Date: Wednesday, December 1, 2021 @ 14:56:57
  Author: felixonmars
Revision: 1059584

archrelease: copy trunk to community-staging-any

Added:
  python-matrix-nio/repos/community-staging-any/
  python-matrix-nio/repos/community-staging-any/PKGBUILD
    (from rev 1059583, python-matrix-nio/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: python-matrix-nio/repos/community-staging-any/PKGBUILD (from rev 1059583, python-matrix-nio/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2021-12-01 14:56:57 UTC (rev 1059584)
@@ -0,0 +1,44 @@
+# Maintainer: Jonas Witschel <diabonas at archlinux.org>
+pkgname=python-matrix-nio
+pkgver=0.18.7
+_tag=c8d831c79eef96caf6e77c9a4421f277a06074b9 # git rev-parse "$pkgver"
+pkgrel=2
+pkgdesc='Python Matrix client library, designed according to sans I/O principles'
+arch=('any')
+url='https://github.com/poljar/matrix-nio'
+license=('ISC')
+depends=('python' 'python-aiofiles' 'python-aiohttp' 'python-aiohttp-socks' 'python-atomicwrites' 
+         'python-cachetools' 'python-future' 'python-h11' 'python-h2' 'python-jsonschema' 'python-logbook' 
+         'python-olm' 'python-peewee' 'python-pycryptodome' 'python-unpaddedbase64')
+makedepends=('git' 'python-dephell' 'python-setuptools')
+checkdepends=('python-aioresponses' 'python-faker' 'python-hpack' 'python-hyperframe' 'python-hypothesis'
+              'python-pytest' 'python-pytest-aiohttp' 'python-pytest-benchmark')
+source=("git+$url.git?signed#tag=$_tag")
+sha512sums=('SKIP')
+validpgpkeys=('689A3B5BC6560AB4C99A2A0581314DA807EF4E22') # Damir Jelić (poljar) <poljar at termina.org.uk>
+
+pkgver() {
+	cd "${pkgname#python-}"
+	git describe | sed 's/\([^-]*-\)g/r\1/;s/-/./g'
+}
+
+prepare() {
+	cd "${pkgname#python-}"
+	dephell deps convert --from pyproject.toml --to setup.py
+}
+
+build() {
+	cd "${pkgname#python-}"
+	python setup.py build
+}
+
+check() {
+	cd "${pkgname#python-}"
+	python -m pytest
+}
+
+package() {
+	cd "${pkgname#python-}"
+	python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+	install -Dm644 LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}