[arch-commits] Commit in (libsolv libsolv/repos libsolv/trunk libsolv/trunk/PKGBUILD)

[Jelle van der Waa]

    Date: Thursday, December 2, 2021 @ 10:48:46
  Author: jelle
Revision: 1061581

libsolv: for python-rpm

Added:
  libsolv/
  libsolv/repos/
  libsolv/trunk/
  libsolv/trunk/PKGBUILD

----------+
 PKGBUILD |   73 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 73 insertions(+)

Added: libsolv/trunk/PKGBUILD
===================================================================
--- libsolv/trunk/PKGBUILD	                        (rev 0)
+++ libsolv/trunk/PKGBUILD	2021-12-02 10:48:46 UTC (rev 1061581)
@@ -0,0 +1,73 @@
+# Maintainer: Jelle van der Waa <jelle at archlinux.org>
+
+pkgname=libsolv
+pkgver=0.7.20
+pkgrel=1
+pkgdesc="Library for solving packages and reading repositories"
+arch=('i686' 'x86_64')
+url="https://github.com/openSUSE/$pkgname"
+license=('custom:BSD')
+depends=('bzip2' 'expat' 'rpm-tools' 'xz' 'zlib' 'zstd')
+makedepends=('cmake' 'perl' 'python' 'ruby' 'swig')
+optdepends=('perl: for perl bindings'
+            'python: for python bindings'
+            'ruby: for ruby bindings')
+source=("$url/archive/$pkgver/$pkgname-$pkgver.tar.gz")
+sha256sums=('8bc0ce89dc8e6277825181db795589b26f913c6d85ca74c833641c1df75c07bc')
+
+build() {
+	cd "$pkgname-$pkgver"
+
+	cmake -B build \
+	      -DCMAKE_BUILD_TYPE=Release \
+	      -DCMAKE_C_FLAGS_RELEASE='-DNDEBUG' \
+	      -DCMAKE_INSTALL_PREFIX=/usr \
+	      -DCMAKE_INSTALL_LIBDIR=lib \
+	      -DUSE_VENDORDIRS=ON \
+	      -DFEDORA=1 \
+	      -DENABLE_APPDATA=ON \
+	      -DENABLE_ARCHREPO=ON \
+	      -DENABLE_BZIP2_COMPRESSION=ON \
+	      -DENABLE_COMPLEX_DEPS=1 \
+	      -DENABLE_COMPS=ON \
+	      -DENABLE_CONDA=ON \
+	      -DENABLE_CUDFREPO=ON \
+	      -DENABLE_DEBIAN=ON \
+	      -DENABLE_HAIKU=OFF \
+	      -DENABLE_HELIXREPO=ON \
+	      -DENABLE_LZMA_COMPRESSION=ON \
+	      -DENABLE_MDKREPO=ON \
+	      -DENABLE_PERL=ON \
+	      -DENABLE_PUBKEY=ON \
+	      -DENABLE_PYTHON=ON \
+	      -DENABLE_RPMDB=ON \
+	      -DENABLE_RPMDB_BYRPMHEADER=ON \
+	      -DENABLE_RPMDB_LIBRPM=ON \
+	      -DENABLE_RPMMD=ON \
+	      -DENABLE_RPMPKG=ON \
+	      -DENABLE_RUBY=ON \
+	      -DENABLE_SUSEREPO=ON \
+	      -DENABLE_TCL=OFF \
+	      -DENABLE_ZSTD_COMPRESSION=ON \
+	      -DMULTI_SEMANTICS=ON \
+	      -DWITH_LIBXML2=OFF \
+
+	make -C build
+}
+
+check() {
+	cd "$pkgname-$pkgver"
+
+	make -C build ARGS="-V" test
+}
+
+package() {
+	cd "$pkgname-$pkgver"
+
+	make -C build DESTDIR="$pkgdir/" install
+
+	install -Dp -m644 LICENSE.BSD "$pkgdir/usr/share/licenses/$pkgname/LICENSE.BSD"
+	install -Dp -m644 README      "$pkgdir/usr/share/doc/$pkgname/README"
+}
+
+# vim: set ft=sh ts=4 sw=4 noet: