[arch-commits] Commit in r8168/repos (2 files)

[Jan Steffens]

    Date: Thursday, December 2, 2021 @ 17:16:21
  Author: heftig
Revision: 1062118

archrelease: copy trunk to community-testing-x86_64

Added:
  r8168/repos/community-testing-x86_64/
  r8168/repos/community-testing-x86_64/PKGBUILD
    (from rev 1062114, r8168/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: r8168/repos/community-testing-x86_64/PKGBUILD (from rev 1062114, r8168/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2021-12-02 17:16:21 UTC (rev 1062118)
@@ -0,0 +1,46 @@
+# Maintainer: Massimiliano Torromeo <massimiliano.torromeo at gmail.com>
+# Contributor: Bob Fanger < bfanger(at)gmail >
+# Contributor: Filip <fila pruda com>, Det < nimetonmaili(at)gmail >
+
+pkgname=r8168
+pkgver=8.049.02
+pkgrel=40
+pkgdesc="A kernel module for Realtek 8168 network cards"
+url="http://www.realtek.com.tw"
+license=("GPL")
+arch=('x86_64')
+makedepends=('linux-headers')
+source=(https://github.com/mtorromeo/r8168/archive/$pkgver/$pkgname-$pkgver.tar.gz
+        https://github.com/mtorromeo/r8168/releases/download/$pkgver/$pkgname-$pkgver.tar.gz.asc)
+sha256sums=('2b12d932e976f8f74b8d9545744c04beb4676dd7bc1d032dde51347ed1d8be24'
+            'SKIP')
+validpgpkeys=('0CADAACF70F64C654E131B3111675C743429DDEF') # Massimiliano Torromeo <massimiliano.torromeo at gmail.com>
+
+build() {
+	cd "$pkgname-$pkgver"
+	# avoid using the Makefile directly -- it doesn't understand
+	# any kernel but the current.
+	make -C /usr/src/linux M="$PWD/src" \
+		ENABLE_USE_FIRMWARE_FILE=y \
+		CONFIG_R8168_NAPI=y \
+		CONFIG_R8168_VLAN=y \
+		CONFIG_ASPM=y \
+		ENABLE_S5WOL=y \
+		ENABLE_EEE=y \
+		modules
+}
+
+package() {
+	depends=('glibc' 'linux')
+
+	local extradir=/usr/lib/modules/$(</usr/src/linux/version)/extramodules
+	cd "$pkgname-$pkgver"
+	install -Dt "$pkgdir$extradir" -m644 src/*.ko
+	find "$pkgdir" -name '*.ko' -exec strip --strip-debug {} +
+	find "$pkgdir" -name '*.ko' -exec xz {} +
+
+	echo "blacklist r8169" | \
+		install -Dm644 /dev/stdin "$pkgdir/usr/lib/modprobe.d/$pkgname.conf"
+}
+
+# vim:set sw=0 noet: