[arch-commits] Commit in pypinyin/repos (2 files)

[Felix Yan]

    Date: Thursday, December 2, 2021 @ 23:31:57
  Author: felixonmars
Revision: 1063098

archrelease: copy trunk to community-staging-any

Added:
  pypinyin/repos/community-staging-any/
  pypinyin/repos/community-staging-any/PKGBUILD
    (from rev 1063097, pypinyin/trunk/PKGBUILD)

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Copied: pypinyin/repos/community-staging-any/PKGBUILD (from rev 1063097, pypinyin/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2021-12-02 23:31:57 UTC (rev 1063098)
@@ -0,0 +1,38 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Štěpán Němec <stepnem at gmail.com>
+
+pkgname=pypinyin
+pkgver=0.42.0
+pkgrel=2
+pkgdesc='Chinese characters transliteration module and tool'
+arch=('any')
+url='https://github.com/mozillazg/python-pinyin'
+license=('MIT')
+depends=('python')
+makedepends=('python-setuptools' 'phrase-pinyin-data' 'pinyin-data')
+checkdepends=('python-pytest-cov')
+source=("https://github.com/mozillazg/python-pinyin/archive/v$pkgver/python-pinyin-$pkgver.tar.gz")
+sha256sums=('56b665413b716ac05d362a99c2917212f8beb126cce381afa393eb39304d00ff')
+
+prepare() {
+  cd python-pinyin-$pkgver
+  ln -s /usr/share/pinyin-data/pinyin.txt pinyin-data/
+  ln -s /usr/share/phrase-pinyin-data/pinyin.txt phrase-pinyin-data/
+}
+
+build() {
+  cd python-pinyin-$pkgver
+  make gen_data
+  python setup.py build
+}
+
+check() {
+  cd python-pinyin-$pkgver
+  pytest pypinyin tests
+}
+
+package() {
+  cd python-pinyin-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+  install -Dm644 LICENSE.txt -t "$pkgdir"/usr/share/licenses/$pkgname/
+}