[arch-commits] Commit in pyzo/repos (2 files)

[Evangelos Foutras]

    Date: Thursday, December 2, 2021 @ 23:39:04
  Author: foutrelis
Revision: 1063217

archrelease: copy trunk to community-staging-any

Added:
  pyzo/repos/community-staging-any/
  pyzo/repos/community-staging-any/PKGBUILD
    (from rev 1063215, pyzo/trunk/PKGBUILD)

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Copied: pyzo/repos/community-staging-any/PKGBUILD (from rev 1063215, pyzo/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2021-12-02 23:39:04 UTC (rev 1063217)
@@ -0,0 +1,41 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Hector Mtz-Seara <hseara.#at#.gmail*.*com>
+
+pkgname=pyzo
+pkgver=4.11.4
+pkgrel=2
+pkgdesc="Cross-platform Python IDE focused on interactivity and introspection, very suitable for scientific computing."
+arch=(any)
+url="https://pyzo.org"
+license=(BSD)
+depends=(python)
+makedepends=(python-setuptools)
+optdepends=(
+    'pyside2: Qt5 backend'
+    'pyside6: Qt6 backend'
+    'python-pyqt5: alternative Qt5 backend'
+    'python-pyqt6: alternative Qt6 backend'
+)
+source=(https://github.com/pyzo/pyzo/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha256sums=('612b778bf73130b3dbffe622b5f16dbfee749becbb004d7cd55f749b38969b24')
+
+build(){
+    cd ${pkgname}-${pkgver}
+    python setup.py build
+}
+
+package(){
+    cd ${pkgname}-${pkgver}
+    python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+
+    # Clean
+    rm "${pkgdir}"/usr/{LICENSE.md,README.md,pyzo.appdata.xml,pyzolauncher.py}
+    install -Dm644 LICENSE.md -t "${pkgdir}"/usr/share/licenses/${pkgname}/
+    install -Dm644 pyzo.appdata.xml -t "${pkgdir}"/usr/share/metainfo/
+    install pyzolauncher.py "${pkgdir}"/usr/bin/pyzo
+
+    install -Dm644 pyzo/resources/pyzo.desktop -t "${pkgdir}"/usr/share/applications/
+    for i in 16 32 48 64 128 256 ; do
+        install -Dm644 pyzo/resources/appicons/pyzologo${i}.png "${pkgdir}"/usr/share/icons/hicolor/${i}x${i}/apps/pyzologo.png
+    done
+}