[arch-commits] Commit in orca/repos (staging-any staging-any/PKGBUILD)

[Felix Yan]

    Date: Thursday, December 2, 2021 @ 23:42:00
  Author: felixonmars
Revision: 430515

archrelease: copy trunk to staging-any

Added:
  orca/repos/staging-any/
  orca/repos/staging-any/PKGBUILD
    (from rev 430514, orca/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: orca/repos/staging-any/PKGBUILD (from rev 430514, orca/trunk/PKGBUILD)
===================================================================
--- staging-any/PKGBUILD	                        (rev 0)
+++ staging-any/PKGBUILD	2021-12-02 23:42:00 UTC (rev 430515)
@@ -0,0 +1,44 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+# Contributor: William Rea <sillywilly at gmail.com>
+
+pkgname=orca
+pkgver=41.0
+pkgrel=2
+pkgdesc="Screen reader for individuals who are blind or visually impaired"
+url="https://wiki.gnome.org/Projects/Orca"
+arch=(any)
+license=(LGPL)
+depends=(gtk3 at-spi2-atk python-atspi python-dbus python-xdg speech-dispatcher liblouis brltty
+         xorg-xmodmap gsettings-desktop-schemas
+         gst-plugins-base # playbin, audiotestsrc, basic decoders
+         gst-plugins-good # pulsesink, more decoders
+)
+makedepends=(itstool intltool git yelp-tools)
+groups=(gnome)
+_commit=493956a8707307c38a5aaf9e314caa9c3f988caa  # tags/ORCA_41_0^0
+source=("git+https://gitlab.gnome.org/GNOME/orca.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed -e 's/ORCA_//' -e 's/_/\./g' -e 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}
+
+# vim:set sw=2 et: