[arch-commits] Commit in z3/repos (2 files)

[Felix Yan]

    Date: Thursday, December 2, 2021 @ 23:42:58
  Author: felixonmars
Revision: 1063271

archrelease: copy trunk to community-staging-x86_64

Added:
  z3/repos/community-staging-x86_64/
  z3/repos/community-staging-x86_64/PKGBUILD
    (from rev 1063270, z3/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: z3/repos/community-staging-x86_64/PKGBUILD (from rev 1063270, z3/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-12-02 23:42:58 UTC (rev 1063271)
@@ -0,0 +1,55 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: rudy.matela
+
+pkgbase=z3
+pkgname=('z3' 'python-z3')
+pkgver=4.8.13
+pkgrel=2
+pkgdesc='High-performance theorem prover'
+url='https://github.com/Z3Prover/z3'
+arch=('x86_64')
+license=('MIT')
+ # 'java-environment-common' 'mono' 'ocaml' 'ocaml-findlib'
+makedepends=('cmake' 'ninja' 'python' 'python-setuptools' 'gcc-libs')
+source=(https://github.com/Z3Prover/z3/archive/z3-$pkgver.tar.gz)
+sha512sums=('c5e8f34525ed3b6b2935d7f01ce2f90f5dd99b4cdd035664b36c967fb1c7f3b05abed45c7288e2261723e73d68728ee91a0f67d92012d86b04598d7b54369c30')
+
+prepare() {
+  cd $pkgbase-z3-$pkgver
+  mkdir -p build
+}
+
+build() {
+  cd $pkgbase-z3-$pkgver/build
+  cmake .. \
+    -GNinja \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DZ3_LINK_TIME_OPTIMIZATION=1 \
+    -DZ3_BUILD_PYTHON_BINDINGS=1 \
+    -DPYTHON_EXECUTABLE=/usr/bin/python
+  ninja
+}
+
+package_z3() {
+  depends=('gcc-libs')
+  provides=('libz3' 'libz3.so')
+  cd $pkgbase-z3-$pkgver/build
+  DESTDIR="$pkgdir" ninja install
+  install -Dm 644 ../LICENSE.txt -t "$pkgdir"/usr/share/licenses/$pkgname
+  rm -r "$pkgdir"/usr/lib/python*
+}
+
+package_python-z3() {
+  depends=('python' 'z3')
+  cd $pkgbase-z3-$pkgver/build
+  DESTDIR="$pkgdir" ninja install
+  install -Dm 644 ../LICENSE.txt -t "$pkgdir"/usr/share/licenses/$pkgname
+  cd "$pkgdir"
+  rm -r usr/include usr/bin usr/lib/{cmake,pkgconfig,lib*}
+  python -m compileall .
+  python -O -m compileall .
+}
+
+# vim: ts=2 sw=2 et: