[arch-commits] Commit in pwndbg/repos (2 files)

[Felix Yan]

    Date: Thursday, December 2, 2021 @ 23:47:13
  Author: felixonmars
Revision: 1063333

archrelease: copy trunk to community-staging-any

Added:
  pwndbg/repos/community-staging-any/
  pwndbg/repos/community-staging-any/PKGBUILD
    (from rev 1063332, pwndbg/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: pwndbg/repos/community-staging-any/PKGBUILD (from rev 1063332, pwndbg/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2021-12-02 23:47:13 UTC (rev 1063333)
@@ -0,0 +1,39 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+
+pkgname=pwndbg
+pkgver=2021.06.22
+pkgrel=2
+pkgdesc='Makes debugging with GDB suck less'
+url='https://github.com/pwndbg/pwndbg'
+arch=('any')
+license=('MIT')
+depends=('gdb' 'python' 'python-capstone' 'python-unicorn' 'python-pycparser' 'python-psutil' 'python-ptrace'
+         'python-pyelftools' 'python-six' 'python-future' 'python-pygments' 'which')
+optdepends=('checksec: checksec command support'
+            'ropper: ropper command support'
+            'ropgadget: ropgadget command support'
+            'radare2: radare2 command support')
+source=(https://github.com/pwndbg/pwndbg/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha512sums=('dac3980ed4ab96bd6f5d584856a5f8bc53388a75962358e77beaaba57fa8be9ebd3a9ac221e5a252a8dd797b76e823c3530dddaa51b1c974e3382ef81d739199')
+b2sums=('d0e4d01cc62ebeb6e7ebdcdb4ff0aa45020e4595eb97b4882ca08662c42446f7e283f8fc4106da5e0e4cd959e864bebd7446f7740bcca44a5aaebdf54ea77f80')
+
+prepare() {
+  cd ${pkgname}-${pkgver}
+  sed '/0L/d' -i ida_script.py
+}
+
+build() {
+  cd ${pkgname}-${pkgver}
+  python -m compileall .
+  python -O -m compileall .
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  install -d "${pkgdir}/usr/share/pwndbg"
+  cp -r *.py pwndbg __pycache__ "${pkgdir}/usr/share/pwndbg"
+  install -Dm 644 README.md FEATURES.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 LICENSE.md -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et: