[arch-commits] Commit in python-gnupg/repos (2 files)

[Felix Yan]

    Date: Friday, December 3, 2021 @ 00:32:00
  Author: felixonmars
Revision: 1063833

archrelease: copy trunk to community-staging-any

Added:
  python-gnupg/repos/community-staging-any/
  python-gnupg/repos/community-staging-any/PKGBUILD
    (from rev 1063832, python-gnupg/trunk/PKGBUILD)

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Copied: python-gnupg/repos/community-staging-any/PKGBUILD (from rev 1063832, python-gnupg/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2021-12-03 00:32:00 UTC (rev 1063833)
@@ -0,0 +1,38 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: NicoHood <archlinux {cat} nicohood {dog} de>
+# Contributor: Sven Klomp <mail at klomp.eu>
+
+pkgname=python-gnupg
+pkgdesc="A wrapper for the Gnu Privacy Guard (GPG or GnuPG)"
+pkgver=0.4.8
+pkgrel=2
+arch=(any)
+url="https://docs.red-dove.com/python-gnupg/"
+license=(BSD)
+depends=(gnupg python)
+makedepends=(python-setuptools)
+checkdepends=(python-pytest)
+source=("https://files.pythonhosted.org/packages/source/${pkgname::1}/${pkgname}/${pkgname}-${pkgver}.tar.gz"{,.asc})
+sha512sums=('fcaa121a356595328a26e8184280f859dfc2771b9692dcf28db2d9b0fdddc77d4c1238665a8e419758ec17320616e7741aacd3638e37d449b86fe5555beef1f6'
+            'SKIP')
+b2sums=('d9ab2fe3ea933a22e731fd70e153e60cc3b158f15e3f8537440c355037092ff7545d29e8d2eab88efb38dcc6e3776c31f537a9c06467b473e93cbc9f0e2ef189'
+        'SKIP')
+validpgpkeys=('CA749061914EAC138E66EADB9147B477339A9B86') # Vinay Sajip (CODE SIGNING KEY) <vinay_sajip at yahoo.co.uk>
+
+build() {
+  cd "${pkgname}-${pkgver}"
+  python setup.py build
+}
+
+check() {
+  cd "${pkgname}-${pkgver}"
+  export NO_EXTERNAL_TESTS='true'
+  pytest -v
+}
+
+package() {
+  cd "${pkgname}-${pkgver}"
+  python setup.py install --optimize=1 --root="${pkgdir}"
+  install -vDm 644 LICENSE.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -vDm 644 README.rst -t "${pkgdir}/usr/share/doc/${pkgname}"
+}