[arch-commits] Commit in img2pdf/repos (2 files)

[Felix Yan]

    Date: Friday, December 3, 2021 @ 00:33:09
  Author: felixonmars
Revision: 1063848

archrelease: copy trunk to community-staging-any

Added:
  img2pdf/repos/community-staging-any/
  img2pdf/repos/community-staging-any/PKGBUILD
    (from rev 1063846, img2pdf/trunk/PKGBUILD)

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Copied: img2pdf/repos/community-staging-any/PKGBUILD (from rev 1063846, img2pdf/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2021-12-03 00:33:09 UTC (rev 1063848)
@@ -0,0 +1,38 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+pkgname=img2pdf
+pkgver=0.4.3
+pkgrel=2
+pkgdesc="Losslessly convert raster images to PDF"
+arch=(any)
+url="https://gitlab.mister-muffin.de/josch/img2pdf"
+license=(LGPL3)
+depends=(python-pillow python-pikepdf python-setuptools)
+checkdepends=(python-pytest python-numpy python-scipy python-lxml
+              colord ghostscript imagemagick mupdf-tools openjpeg2 poppler perl-image-exiftool netpbm)
+source=(https://files.pythonhosted.org/packages/source/i/${pkgname}/${pkgname}-${pkgver}.tar.gz)
+sha256sums=('8e51c5043efa95d751481b516071a006f87c2a4059961a9ac43ec238915de09f')
+
+build() {
+    cd ${pkgname}-${pkgver}
+    python setup.py build
+}
+
+check() {
+    cd ${pkgname}-${pkgver}
+    # Different output on Arch?
+    sed -e 's|Joint Photographic Experts Group JFIF format|JPEG|g' \
+        -e 's|JPEG-2000 File Format Syntax|JP2|g' \
+        -e 's|Portable Network Graphics|PNG|g' \
+        -e 's|Tagged Image File Format|TIFF|g' \
+        -e 's|CompuServe graphics interchange format|GIF|g' \
+        -i src/img2pdf_test.py
+    sed 's|usr/share/color/icc/sRGB.icc|usr/share/color/icc/colord/sRGB.icc|g' -i src/img2pdf_test.py
+    # Failures with depth
+    python -m pytest || echo "Tests failed"
+}
+
+package() {
+    cd ${pkgname}-${pkgver}
+    python setup.py install --skip-build --prefix=/usr --root="${pkgdir}" --optimize=1
+}