[arch-commits] Commit in py3status/repos (2 files)
Felix Yan
felixonmars at gemini.archlinux.org
Fri Dec 3 00:39:08 UTC 2021
Date: Friday, December 3, 2021 @ 00:39:07
Author: felixonmars
Revision: 1063932
archrelease: copy trunk to community-staging-any
Added:
py3status/repos/community-staging-any/
py3status/repos/community-staging-any/PKGBUILD
(from rev 1063930, py3status/trunk/PKGBUILD)
----------+
PKGBUILD | 44 ++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 44 insertions(+)
Copied: py3status/repos/community-staging-any/PKGBUILD (from rev 1063930, py3status/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD (rev 0)
+++ community-staging-any/PKGBUILD 2021-12-03 00:39:07 UTC (rev 1063932)
@@ -0,0 +1,44 @@
+# Maintainer: Morten Linderud <foxboron at archlinux.org>
+# Maintainer: Jonas Witschel <diabonas at archlinux.org>
+# Contributor: Maxim Baz <$pkgname at maximbaz dot com>
+# Contributor: Alexis "Horgix" Chotard <alexis.horgix.chotard at gmail.com>
+# Contributor: carstene1ns <arch carsten-teibes de> - http://git.io/ctPKG
+
+pkgname=py3status
+pkgver=3.40
+pkgrel=2
+pkgdesc="An extensible i3status replacement/wrapper written in python"
+url="https://www.ultrabug.fr/tag/py3status/"
+arch=('any')
+license=('BSD')
+depends=('python' 'python-setuptools')
+checkdepends=('python-pytest-runner')
+optdepends=('i3status: for i3status modules'
+ 'i3blocks: for i3blocks modules'
+ 'python-pyudev: for udev event monitoring'
+ 'python-pydbus: for modules that rely on D-Bus'
+ 'python-pytz: for the clock module'
+ 'python-tzlocal: for the clock module'
+ 'pacman-contrib: for the arch_updates module')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/ultrabug/py3status/archive/$pkgver.tar.gz")
+sha256sums=('84885ec8a43626dcd7576b9cad029406c98675ca00ba66ff124d7607290d2b66')
+
+build() {
+ cd "$pkgname-$pkgver"
+ python setup.py build
+}
+
+check() {
+ cd "$pkgname-$pkgver"
+ python setup.py pytest
+}
+
+package() {
+ cd "$pkgname-$pkgver"
+ python setup.py install --root="$pkgdir/" --optimize=1 --skip-build
+ install -d "$pkgdir/usr/share/doc/$pkgname"{,/dev-guide,/user-guide}
+ install -m644 docs/*.md README.md CHANGELOG "$pkgdir/usr/share/doc/$pkgname"
+ install -m644 docs/dev-guide/* "$pkgdir/usr/share/doc/$pkgname/dev-guide"
+ install -m644 docs/user-guide/* "$pkgdir/usr/share/doc/$pkgname/user-guide"
+ install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
More information about the arch-commits
mailing list