[arch-commits] Commit in mlt/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Felix Yan]

    Date: Friday, December 3, 2021 @ 00:39:15
  Author: felixonmars
Revision: 430551

archrelease: copy trunk to staging-x86_64

Added:
  mlt/repos/staging-x86_64/
  mlt/repos/staging-x86_64/PKGBUILD
    (from rev 430550, mlt/trunk/PKGBUILD)

----------+
 PKGBUILD |   56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

Copied: mlt/repos/staging-x86_64/PKGBUILD (from rev 430550, mlt/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2021-12-03 00:39:15 UTC (rev 430551)
@@ -0,0 +1,56 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Fabian Schoelzel <myfirstname.mylastname at googlemail.com>
+# Contributor: funkyou <spamopfer at nickname.berlin.de>
+# Contributor: tardo <tardo at nagi-fanboi.net>
+# Contributor: Stefan Husmann <stefan-husmann at t-online.de>
+# Contributor: Gustavo Alvarez <sl1pkn07 at gmail.com>
+
+pkgname=mlt
+pkgver=7.2.0
+pkgrel=3
+pkgdesc='An open source multimedia framework'
+arch=(x86_64)
+url='https://www.mltframework.org'
+license=(GPL)
+depends=(libebur128)
+optdepends=('sdl_image: SDL1 plugin'
+            'sdl2: SDL2 plugin'
+            'libsamplerate: libavresample plugin'
+            'sox: SOX (Audio Swiss Army Knife) plugin'
+            'ffmpeg: ffmpeg plugin'
+            'vid.stab: video stabilize plugin'
+            'qt5-svg: Qt5 plugins'
+            'jack: JACK sound output plugin'
+            'ladspa: LADSPA plugins'
+            'libexif: auto rotate plugin'
+            'frei0r-plugins: for additional effects'
+            'movit: opengl plugin'
+            'opencv: openCV plugin'
+            'rubberband: audio pitch plugin'
+            'gdk-pixbuf2: gdk plugin'
+            'pango: gdk plugin'
+            'rtaudio: rtaudio plugin'
+            'python: python bindings')
+makedepends=(cmake ladspa frei0r-plugins libdv sdl_image libsamplerate sox ffmpeg vid.stab qt5-svg
+             jack libexif python swig movit eigen opencv rubberband gdk-pixbuf2 pango rtaudio imagemagick)
+source=(https://github.com/mltframework/mlt/archive/v$pkgver/$pkgname-$pkgver.tar.gz
+        https://github.com/mltframework/mlt/commit/17e34fd3.patch)
+sha256sums=('34b737fae61dabddf3ec64477298decb9b2076388ccbda7e50114996b268086d'
+            'b9392939c907251d2039fdb66450e29fbfb38c77b3626c618e94fea34c21a711')
+
+prepare() {
+  patch -d $pkgname-$pkgver -p1 < 17e34fd3.patch # Fix sdl module underlinking
+}
+
+build() {
+  cmake -B build -S $pkgname-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DMOD_OPENCV=ON \
+    -DSWIG_PYTHON=ON
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+}