[arch-commits] Commit in tpm2-pkcs11/repos (2 files)

[Evangelos Foutras]

    Date: Friday, December 3, 2021 @ 00:41:31
  Author: foutrelis
Revision: 1063962

archrelease: copy trunk to community-staging-x86_64

Added:
  tpm2-pkcs11/repos/community-staging-x86_64/
  tpm2-pkcs11/repos/community-staging-x86_64/PKGBUILD
    (from rev 1063961, tpm2-pkcs11/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: tpm2-pkcs11/repos/community-staging-x86_64/PKGBUILD (from rev 1063961, tpm2-pkcs11/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-12-03 00:41:31 UTC (rev 1063962)
@@ -0,0 +1,39 @@
+# Maintainer: Jonas Witschel <diabonas at archlinux.org>
+pkgname=tpm2-pkcs11
+pkgver=1.7.0
+pkgrel=3
+pkgdesc='PKCS#11 interface for Trusted Platform Module 2.0 hardware'
+arch=('x86_64')
+url='https://github.com/tpm2-software/tpm2-pkcs11'
+license=('BSD')
+depends=('libyaml' 'openssl' 'python' 'python-bcrypt' 'python-cryptography' 'python-pyasn1-modules' 'python-yaml' 'sqlite'
+         'tpm2-tools' 'tpm2-tss' 'libtss2-esys.so' 'libtss2-fapi.so' 'libtss2-mu.so' 'libtss2-rc.so' 'libtss2-tctildr.so')
+makedepends=('cmocka' 'python-setuptools')
+checkdepends=('expect' 'iproute2' 'java-hamcrest' 'junit' 'libp11' 'opensc' 'openssh'
+              'python-python-pkcs11' 'swtpm' 'tpm2-abrmd' 'tpm2-tss-engine' 'wget' 'xxd')
+source=("$url/releases/download/$pkgver/$pkgname-$pkgver.tar.gz"{,.asc})
+sha512sums=('eb2736a7ef00fefa91bb70cc96d94d1c7b6ce3701ab12301658b7b076d8fca93bc590c7cdba5a84934b6bd09dad252b13670804c686e76a65b03c7ef6d96427d'
+            'SKIP')
+validpgpkeys=('5B482B8E3E19DA7C978E1D016DE2E9078E1F50C1') # William Roberts (Bill Roberts) <william.c.roberts at intel.com>
+
+build() {
+	cd "$pkgname-$pkgver"
+	export CLASSPATH="/usr/share/java/junit.jar:/usr/share/java/hamcrest-core.jar:$CLASSPATH"
+	./configure --prefix=/usr --enable-unit $( ((CHECKFUNC)) && echo --enable-integration)
+	make
+	cd tools
+	python setup.py build
+}
+
+check() {
+	cd "$pkgname-$pkgver"
+	make check
+}
+
+package() {
+	cd "$pkgname-$pkgver"
+	make DESTDIR="$pkgdir" install
+	install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
+	cd tools
+	python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+}