[arch-commits] Commit in urh/repos (2 files)

[Felix Yan]

    Date: Friday, December 3, 2021 @ 00:42:53
  Author: felixonmars
Revision: 1063982

archrelease: copy trunk to community-staging-x86_64

Added:
  urh/repos/community-staging-x86_64/
  urh/repos/community-staging-x86_64/PKGBUILD
    (from rev 1063978, urh/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: urh/repos/community-staging-x86_64/PKGBUILD (from rev 1063978, urh/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-12-03 00:42:53 UTC (rev 1063982)
@@ -0,0 +1,49 @@
+# Maintainer: Filipe Laíns (FFY00) <lains at archlinuc.org>
+# Contributor: Johannes Pohl <johannes.pohl90 at gmail.com>
+
+pkgname=urh
+pkgver=2.9.2
+pkgrel=4
+pkgdesc='Universal Radio Hacker: investigate wireless protocols like a boss'
+arch=('x86_64')
+url='https://github.com/jopohl/urh'
+license=('GPL3')
+depends=('python' 'python-pyqt5' 'python-numpy' 'python-psutil' 'cython')
+makedepends=('gcc' 'python-setuptools' 'airspy' 'hackrf' 'libuhd' 'limesuite' 'rtl-sdr' 'bladerf' 'libiio')
+checkdepends=('python-pytest-runner' 'python-pytest-xdist' 'xorg-server-xvfb')
+optdepends=('airspy: Airspy backend'
+            'cython: compiling native modules inside URH'
+            'hackrf: HackRF backend'
+            'libuhd: USRP backend'
+            'limesuite: LimeSDR backend'
+            'rtl-sdr: RTL-SDR backend'
+            'gnuradio: GNURadio backend'
+            'bladerf: BladeRF backend'
+            'libiio: IIO backend (PlutoSDR)'
+            'gnuradio-osmosdr: OsmoSDR backend, via GNURadio'
+            'python-pyaudio: Soundcard backend')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/jopohl/urh/archive/v$pkgver.tar.gz")
+sha512sums=('4cf0ae173be467257d64f9d27aad52ffa73ef3a1b428e8bb8ca5d5647ddca48418f0625cc14b93f434ecb92095162a560f0a89e4e378fc98c38393af44425854')
+
+build() {
+  cd $pkgname-$pkgver
+
+  python setup.py build build_ext
+  python src/urh/cythonext/build.py
+}
+
+check() {
+  cd $pkgname-$pkgver
+
+  xvfb-run pytest --boxed
+}
+
+package() {
+  cd $pkgname-$pkgver
+
+  python setup.py install --root="$pkgdir" -O1 --skip-build
+
+  install -Dm644 ./data/urh.desktop "$pkgdir"/usr/share/applications/urh.desktop
+  install -Dm 644 data/icons/appicon.png "$pkgdir"/usr/share/pixmaps/urh.png
+  install -Dm 644 README.md "$pkgdir"/usr/share/doc/$pkgname/README
+}