[arch-commits] Commit in nuitka/repos (2 files)

[Felix Yan]

    Date: Friday, December 3, 2021 @ 01:56:30
  Author: felixonmars
Revision: 1064693

archrelease: copy trunk to community-staging-any

Added:
  nuitka/repos/community-staging-any/
  nuitka/repos/community-staging-any/PKGBUILD
    (from rev 1064692, nuitka/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: nuitka/repos/community-staging-any/PKGBUILD (from rev 1064692, nuitka/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2021-12-03 01:56:30 UTC (rev 1064693)
@@ -0,0 +1,45 @@
+# Maintainer: Alexander F. Rødseth <xyproto at archlinux.org>
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Panagiotis Mavrogiorgos <pmav99 at gmail.com>
+
+pkgname=nuitka
+pkgver=0.6.18
+pkgrel=2
+pkgdesc='Python compiler with full language support and CPython compatibility'
+arch=(any)
+url='https://nuitka.net/'
+license=(Apache)
+depends=(python-appdirs scons)
+makedepends=(python-setuptools)
+checkdepends=(ccache fuse2 patchelf python-boto3 python-brotli strace)
+optdepends=('ccache: for build caching'
+            'chrpath: for building standalone executables'
+            'pyside2: for using Qt5 APIs')
+options=(!emptydirs)
+source=("https://files.pythonhosted.org/packages/source/N/${pkgname^}/${pkgname^}-${pkgver}.tar.gz")
+sha512sums=('d727f569b0efef133eaa2f647bdc215cc2f87fe762682691909d5a3d9f55299805766d0fdc0bfae09388b0eb3a450d6211a5252e92039d23ccb130117eaa412b')
+b2sums=('5ef7da5b1f065d7ff23c82b5cb26e001c486546f4a169d9a5db442d9ff2e91c8dcc052232b6355c19f9388ca34d7b4c7199c42922ba3b4a6284101d77430dac1')
+
+prepare() {
+  cd ${pkgname^}-$pkgver
+  # in our build environment /etc/os-release will not exist, but /usr/lib/os-release will
+  sed -e 's|/etc/os-release|/usr/lib/os-release|' -i nuitka/utils/Utils.py
+}
+
+build() {
+  cd ${pkgname^}-$pkgver
+  python setup.py build
+}
+
+check() {
+  cd ${pkgname^}-$pkgver
+  # skip tests for other interpreters and those that require network access
+  # NOTE: the test uses "strace", which is currently not supported by the reproducible build system
+  ./tests/run-tests --no-other-python --skip-onefile-tests --skip-other-cpython-tests
+}
+
+package() {
+  cd ${pkgname^}-$pkgver
+  python setup.py install --optimize=1 --root="$pkgdir" --skip-build
+  install -Dm644 {Changelog,Developer_Manual,README}.rst -t "$pkgdir/usr/share/doc/$pkgname/"
+}