[arch-commits] Commit in qtile/repos (3 files)

[Evangelos Foutras]

    Date: Saturday, December 4, 2021 @ 00:42:07
  Author: foutrelis
Revision: 1064974

archrelease: copy trunk to community-staging-x86_64

Added:
  qtile/repos/community-staging-x86_64/
  qtile/repos/community-staging-x86_64/PKGBUILD
    (from rev 1064973, qtile/trunk/PKGBUILD)
  qtile/repos/community-staging-x86_64/qtile.install
    (from rev 1064973, qtile/trunk/qtile.install)

---------------+
 PKGBUILD      |   96 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 qtile.install |   10 +++++
 2 files changed, 106 insertions(+)

Copied: qtile/repos/community-staging-x86_64/PKGBUILD (from rev 1064973, qtile/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-12-04 00:42:07 UTC (rev 1064974)
@@ -0,0 +1,96 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+pkgname=qtile
+pkgver=0.18.1
+pkgrel=4
+pkgdesc="A full-featured, pure-Python tiling window manager"
+arch=(x86_64)
+url="http://www.qtile.org"
+license=(MIT)
+# remove python-setuptools once upstream does not require it for version anymore:
+# https://github.com/qtile/qtile/issues/2809
+depends=(
+  gdk-pixbuf2
+  glibc
+  libnotify
+  librsvg
+  pango
+  python-cairocffi
+  python-cffi
+  python-xcffib
+  python-gobject
+  python-setuptools
+)
+makedepends=(
+  git
+  libpulse
+  python-setuptools-scm
+)
+checkdepends=(
+  graphviz
+  gtk3
+  imagemagick
+  lm_sensors
+  procps-ng
+  python-bowler
+  python-dbus-next
+  python-gobject
+  python-pytest
+  python-pywlroots
+  python-xdg
+  xorg-server-xephyr
+  xorg-server-xvfb
+  xorg-xrandr
+)
+optdepends=(
+  'alsa-utils: for volume widget'
+  'canto-daemon: for canto widget'
+  'cmus: for cmus widget'
+  'jupyter_console: for interaction with qtile via Jupyter'
+  'khal: for khal_calendar widget'
+  'libpulse: for pulse_volume and pulseaudio_ffi widget'
+  'lm_sensors: for sensors widget'
+  'moc: for moc widget'
+  'python-dbus-next: for utils, notifications and several widgets'
+  'python-iwlib: for wlan widget'
+  'python-keyring: for imapwidget widget'
+  'python-mpd2: mpd2widget widget'
+  'python-psutil: graph, net and memory widget'
+  'python-pywlroots: for experimental wayland support'
+  'python-setproctitle: change process name to qtile'
+  'python-xdg: launchbar widget'
+)
+install="${pkgname}.install"
+source=("git+https://github.com/qtile/qtile#tag=v${pkgver}?signed")
+sha512sums=('SKIP')
+b2sums=('SKIP')
+validpgpkeys=(
+  '3CCAB226289DE0160C61BDB418D18F1BC464DCA3' # Tycho Andersen <tycho at tycho.pizza>
+  '35D92E7CC7357A81173EA1C974F9FDD20984FBEC' # Matt Colligan <mcol at posteo.net>
+)
+
+build() {
+  cd "${pkgname}"
+  python setup.py build
+  ./scripts/ffibuild
+}
+
+check() {
+  cd "${pkgname}"
+  export LC_TYPE=en_US.UTF-8
+  pytest -vv --backend x11 --backend wayland
+}
+
+package() {
+  cd "${pkgname}"
+  python setup.py install --optimize=1 --root="${pkgdir}"
+  # license
+  install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}/"
+  # config
+  install -vDm 644 libqtile/resources/default_config.py -t "${pkgdir}/usr/share/doc/${pkgname}/"
+  # desktop files
+  install -vDm 644 "resources/${pkgname}.desktop" -t "${pkgdir}/usr/share/xsessions/"
+  install -vDm 644 "resources/${pkgname}-wayland.desktop" -t "${pkgdir}/usr/share/wayland-sessions/"
+  # docs
+  install -vDm 644 {CHANGELOG,README.rst} -t "${pkgdir}/usr/share/doc/${pkgname}/"
+}

Copied: qtile/repos/community-staging-x86_64/qtile.install (from rev 1064973, qtile/trunk/qtile.install)
===================================================================
--- community-staging-x86_64/qtile.install	                        (rev 0)
+++ community-staging-x86_64/qtile.install	2021-12-04 00:42:07 UTC (rev 1064974)
@@ -0,0 +1,10 @@
+# arg 1:  the new package version
+# arg 2:  the old package version
+post_upgrade() {
+  if (( "$(vercmp "$2" '0.17.0-1')" < 0 )); then
+    printf "WARNING: Major config and functionality changes. A restart (not reload) of qtile is required.\n"
+  fi
+  if (( "$(vercmp "$2" '0.18.0-1')" < 0 )); then
+    printf "WARNING: Major config changes. Make sure to read /usr/share/doc/qtile/CHANGELOG.\n"
+  fi
+}