[arch-commits] Commit in mitmproxy/repos (2 files)

[Evangelos Foutras]

    Date: Tuesday, December 7, 2021 @ 14:33:28
  Author: foutrelis
Revision: 1065548

archrelease: copy trunk to community-staging-any

Added:
  mitmproxy/repos/community-staging-any/
  mitmproxy/repos/community-staging-any/PKGBUILD
    (from rev 1065547, mitmproxy/trunk/PKGBUILD)

----------+
 PKGBUILD |   57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

Copied: mitmproxy/repos/community-staging-any/PKGBUILD (from rev 1065547, mitmproxy/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2021-12-07 14:33:28 UTC (rev 1065548)
@@ -0,0 +1,57 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Filipe Laíns (FFY00) <lains at archlinux.org>
+# Contributor: Simon 'ALSimon' Gilliot <simon at gilliot.fr>
+# Contributor: Olivier Biesmans <olivier at biesmans dot fr>
+# Contributor: Dobroslaw Kijowski
+
+pkgname=mitmproxy
+pkgver=7.0.4
+pkgrel=2
+pkgdesc='SSL-capable man-in-the-middle HTTP proxy'
+arch=('any')
+url='https://mitmproxy.org'
+license=('MIT')
+depends=('python-asgiref' 'python-blinker' 'python-brotli' 'python-click' 'python-cryptography'
+         'python-flask' 'python-h11' 'python-h2' 'python-hyperframe' 'python-kaitaistruct'
+         'python-ldap3' 'python-msgpack' 'python-passlib' 'python-protobuf' 'python-pyopenssl'
+         'python-pyparsing' 'python-pyperclip' 'python-ruamel-yaml' 'python-setuptools'
+         'python-sortedcontainers' 'python-tornado' 'python-urwid' 'python-wsproto'
+         'python-publicsuffix2' 'python-zstandard')
+checkdepends=('python-asynctest' 'python-parver' 'python-pytest-runner' 'python-pytest-asyncio'
+              'python-requests' 'python-hypothesis')
+provides=('pathod')
+conflicts=('pathod')
+replaces=('pathod')
+source=("https://github.com/mitmproxy/mitmproxy/archive/v$pkgver/$pkgname-$pkgver.tar.gz")
+sha512sums=('4224b44e609f84b974b5419c6ceb576845957968c786ee437bffb5fa5df685ce0712d5ef8c402d40c568406242f44692cc7f04037fadd19ecece8b112d73b7ae')
+
+prepare() {
+  cd $pkgname-$pkgver
+
+  # Let's remove all the upper bounds and use system ca-certificatescate store
+  # We have an old protobuf, but this should not be an issue
+  sed -e '/certifi/d' \
+      -e 's/, *<[0-9=.]*//' \
+      -e 's/protobuf>=3.14/protobuf>=3/' \
+      -i setup.py
+  sed -e '/import certifi/d' \
+      -e 's|certifi.where()|"/etc/ssl/certs/ca-certificates.crt"|' \
+      -i mitmproxy/net/tls.py
+}
+
+build() {
+  cd $pkgname-$pkgver
+  python setup.py build
+}
+
+check() {
+  cd $pkgname-$pkgver
+  python setup.py pytest --addopts "--deselect test/mitmproxy/test_version.py::test_get_version"
+}
+
+package() {
+  cd $pkgname-$pkgver
+  python setup.py install --root="$pkgdir" -O1
+
+  install -Dm 644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}