[arch-commits] Commit in python-pep621/repos (community-any community-any/PKGBUILD)

[Filipe Laíns]

    Date: Thursday, December 9, 2021 @ 00:47:30
  Author: ffy00
Revision: 1065735

archrelease: copy trunk to community-any

Added:
  python-pep621/repos/community-any/
  python-pep621/repos/community-any/PKGBUILD
    (from rev 1065734, python-pep621/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: python-pep621/repos/community-any/PKGBUILD (from rev 1065734, python-pep621/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2021-12-09 00:47:30 UTC (rev 1065735)
@@ -0,0 +1,46 @@
+# Maintainer: Filipe Laíns (FFY00) <lains at archlinux.org>
+
+pkgname=python-pep621
+pkgver=0.4.0
+pkgrel=1
+pkgdesc='PEP 621 metadata parsing'
+arch=('any')
+url='https://github.com/FFY00/python-pep621'
+license=('MIT')
+depends=('python-packaging')
+makedepends=('git' 'python-setuptools' 'python-sphinx' 'python-sphinx-autodoc-typehints' 'python-sphinx-furo')
+checkdepends=('python-pytest' 'python-tomli')
+source=("git+$url#tag=$pkgver?signed")
+validpgpkeys=('3DCE51D60930EBA47858BA4146F633CBB0EB4BF2') # Filipe Laíns (FFY00) <lains at archlinux.org>
+sha512sums=('SKIP')
+
+prepare() {
+  echo 'from setuptools import setup; setup()' >$pkgname/setup.py
+}
+
+build() {
+  cd $pkgname
+
+  python setup.py build
+
+  PYTHONPATH=. sphinx-build -b dirhtml -v docs docs/build/html
+}
+
+check() {
+  cd $pkgname
+
+  python -m pytest
+}
+
+package() {
+  cd $pkgname
+
+  python setup.py install --root="$pkgdir" --skip-build
+  python -m compileall --invalidation-mode=checked-hash "$pkgdir"
+
+  install -dm 755 "$pkgdir"/usr/share/doc/$pkgname
+  cp -r -a --no-preserve=ownership docs/build/html "$pkgdir"/usr/share/doc/$pkgname
+  rm -rf "$pkgdir"/usr/share/doc/$pkgname/html/.doctrees
+
+  install -Dm 644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}