[arch-commits] Commit in akonadi/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Antonio Rojas]

    Date: Thursday, December 9, 2021 @ 10:01:02
  Author: arojas
Revision: 430867

archrelease: copy trunk to testing-x86_64

Added:
  akonadi/repos/testing-x86_64/
  akonadi/repos/testing-x86_64/PKGBUILD
    (from rev 430866, akonadi/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: akonadi/repos/testing-x86_64/PKGBUILD (from rev 430866, akonadi/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2021-12-09 10:01:02 UTC (rev 430867)
@@ -0,0 +1,43 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Pierre Schmitz <pierre at archlinux.de>
+
+pkgbase=akonadi
+pkgname=(akonadi libakonadi)
+pkgver=21.12.0
+pkgrel=1
+pkgdesc='PIM layer, which provides an asynchronous API to access all kind of PIM data'
+arch=(x86_64)
+url='https://kontact.kde.org'
+license=(LGPL)
+makedepends=(extra-cmake-modules postgresql qt5-tools boost kitemmodels kaccounts-integration doxygen)
+source=(https://download.kde.org/stable/release-service/$pkgver/src/$pkgname-$pkgver.tar.xz{,.sig})
+sha256sums=('23bf7036b9b6f5d8ce01535c2698d54768bfa7c70c9257e4c92dca4d319cb8f3'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87  # Christoph Feck <cfeck at kde.org>
+              D81C0CB38EB725EF6691C385BB463350D6EF31EF) # Heiko Becker <heiko.becker at kde.org>
+
+build() {
+  cmake -B build -S $pkgname-$pkgver \
+    -DBUILD_TESTING=OFF \
+    -DBUILD_QCH=ON
+  cmake --build build
+}
+
+package_libakonadi() {
+  pkgdesc='Libraries used by applications based on Akonadi'
+  depends=(kitemmodels kaccounts-integration)
+
+  DESTDIR="$pkgdir" cmake --install build
+  rm -r "$pkgdir"/usr/bin # Provided by akonadi
+}
+
+package_akonadi() {
+  depends=(libakonadi mariadb)
+  optdepends=('postgresql: PostgreSQL backend')
+
+  DESTDIR="$pkgdir" cmake --install build
+  rm -r "$pkgdir"/{etc,usr/{include,lib,share}} # Provided by libakonadi
+}