[arch-commits] Commit in kdeconnect/repos (3 files)

[Antonio Rojas]

    Date: Thursday, December 9, 2021 @ 10:16:05
  Author: arojas
Revision: 430990

archrelease: copy trunk to testing-x86_64

Added:
  kdeconnect/repos/testing-x86_64/
  kdeconnect/repos/testing-x86_64/PKGBUILD
    (from rev 430989, kdeconnect/trunk/PKGBUILD)
  kdeconnect/repos/testing-x86_64/kdeconnect-openssh-8.8.patch
    (from rev 430989, kdeconnect/trunk/kdeconnect-openssh-8.8.patch)

------------------------------+
 PKGBUILD                     |   38 ++++++++++++++++++++++++++++++++++++++
 kdeconnect-openssh-8.8.patch |   12 ++++++++++++
 2 files changed, 50 insertions(+)

Copied: kdeconnect/repos/testing-x86_64/PKGBUILD (from rev 430989, kdeconnect/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2021-12-09 10:16:05 UTC (rev 430990)
@@ -0,0 +1,38 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Kuba Serafinowski <zizzfizzix(at)gmail(dot)com>
+
+pkgname=kdeconnect
+pkgver=21.12.0
+pkgrel=1
+pkgdesc='Adds communication between KDE and your smartphone'
+url='https://kdeconnect.kde.org/'
+arch=(x86_64)
+license=(GPL)
+groups=(kde-applications kde-network)
+depends=(kcmutils kwayland libfakekey qca-qt5 kpeoplevcard pulseaudio-qt qqc2-desktop-style hicolor-icon-theme)
+makedepends=(extra-cmake-modules kdoctools)
+optdepends=('sshfs: remote filesystem browser' 'python-nautilus: Nautilus integration' 'qt5-tools: for some runcommand plugin actions')
+source=(https://download.kde.org/stable/release-service/$pkgver/src/$pkgname-kde-$pkgver.tar.xz{,.sig}
+        kdeconnect-openssh-8.8.patch)
+sha256sums=('519e1d03cef6c8b68902be7907fada4988b34c20816a977077576bf168369d4a'
+            'SKIP'
+            'e1b43f8b3e0b2a521277d70d4fdeb8dff714f6855f33ae1c3c7d8f03fe69dbb9')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87  # Christoph Feck <cfeck at kde.org>
+              D81C0CB38EB725EF6691C385BB463350D6EF31EF) # Heiko Becker <heiko.becker at kde.org>
+
+prepare() {
+  patch -d $pkgname-kde-$pkgver -p1 < kdeconnect-openssh-8.8.patch # Fix file browsing with openssh 8.8
+}
+
+build() {
+  cmake -B build -S $pkgname-kde-$pkgver \
+    -DBUILD_TESTING=OFF \
+    -DCMAKE_INSTALL_LIBEXECDIR=lib
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+}

Copied: kdeconnect/repos/testing-x86_64/kdeconnect-openssh-8.8.patch (from rev 430989, kdeconnect/trunk/kdeconnect-openssh-8.8.patch)
===================================================================
--- testing-x86_64/kdeconnect-openssh-8.8.patch	                        (rev 0)
+++ testing-x86_64/kdeconnect-openssh-8.8.patch	2021-12-09 10:16:05 UTC (rev 430990)
@@ -0,0 +1,12 @@
+diff --git a/plugins/sftp/mounter.cpp b/plugins/sftp/mounter.cpp
+index 2a484186..23ddc616 100644
+--- a/plugins/sftp/mounter.cpp
++++ b/plugins/sftp/mounter.cpp
+@@ -129,6 +129,7 @@ void Mounter::onPackageReceived(const NetworkPacket& np)
+         << QStringLiteral("-o") << QStringLiteral("StrictHostKeyChecking=no") //Do not ask for confirmation because it is not a known host
+         << QStringLiteral("-o") << QStringLiteral("UserKnownHostsFile=/dev/null") //Prevent storing as a known host
+         << QStringLiteral("-o") << QStringLiteral("HostKeyAlgorithms=+ssh-dss\\,ssh-rsa") //https://bugs.kde.org/show_bug.cgi?id=351725
++        << QStringLiteral("-o") << QStringLiteral("PubkeyAcceptedKeyTypes=+ssh-rsa")
+         << QStringLiteral("-o") << QStringLiteral("uid=") + QString::number(getuid())
+         << QStringLiteral("-o") << QStringLiteral("gid=") + QString::number(getgid())
+         << QStringLiteral("-o") << QStringLiteral("reconnect")