[arch-commits] Commit in godot/repos (2 files)

[Sven-Hendrik Haase]

    Date: Friday, December 10, 2021 @ 02:18:34
  Author: svenstaro
Revision: 1065965

archrelease: copy trunk to community-staging-x86_64

Added:
  godot/repos/community-staging-x86_64/
  godot/repos/community-staging-x86_64/PKGBUILD
    (from rev 1065964, godot/trunk/PKGBUILD)

----------+
 PKGBUILD |   63 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 63 insertions(+)

Copied: godot/repos/community-staging-x86_64/PKGBUILD (from rev 1065964, godot/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-12-10 02:18:34 UTC (rev 1065965)
@@ -0,0 +1,63 @@
+# Maintainer: Alexander F. Rødseth <xyproto at archlinux.org>
+# Contributor: loqs
+# Contributor: Jorge Araya Navarro <jorgejavieran at yahoo.com.mx>
+# Contributor: Cristian Porras <porrascristian at gmail.com>
+# Contributor: Matthew Bentley <matthew at mtbentley.us>
+
+pkgname=godot
+pkgver=3.4
+pkgrel=2
+pkgdesc='Advanced cross-platform 2D and 3D game engine'
+url='https://godotengine.org'
+license=(MIT)
+arch=(x86_64)
+makedepends=(gcc scons yasm alsa-lib pulseaudio)
+depends=(bullet embree freetype2 libglvnd libtheora libvorbis libvpx libwebp
+         libwslay libxcursor libxi libxinerama libxrandr mbedtls miniupnpc opusfile)
+optdepends=(alsa-lib pulseaudio)
+source=("$pkgname-$pkgver.tar.gz::https://github.com/godotengine/godot/archive/$pkgver-stable.tar.gz")
+b2sums=('372a48f20b5b04a23ea0c43ee8b4364f51f4223e61abf4b4375721c1fe20662419ec0d06bf1a980ce3b2bfadb24de3f5543c7cda87778df49043c355d65fcf6d')
+
+prepare() {
+  # Disable the check that adds -no-pie to LINKFLAGS, for gcc != 6
+  sed -i 's,0] >,0] =,g' $pkgname-$pkgver-stable/platform/x11/detect.py
+}
+
+build() {
+  # Not unbundled yet:
+  #  enet (contains no upstreamed IPv6 support)
+  #  libsquish, recast, xatlas
+  #  AUR: libwebm, squish
+  local to_unbundle="bullet certs embree freetype libogg libpng libtheora libvorbis libvpx libwebp mbedtls miniupnpc opus pcre2 wslay zlib zstd"
+  local system_libs=""
+  for _lib in $to_unbundle; do
+    system_libs+="builtin_"$_lib"=no "
+    rm -rf thirdparty/$_lib
+  done
+
+  cd $pkgname-$pkgver-stable
+  export BUILD_NAME=arch_linux
+  scons -j16 \
+    bits=64 \
+    colored=yes \
+    platform=x11 \
+    pulseaudio=yes \
+    system_certs_path=/etc/ssl/certs/ca-certificates.crt \
+    target=release_debug \
+    tools=yes \
+    use_llvm=no \
+    CFLAGS="$CFLAGS -fPIC -Wl,-z,relro,-z,now" \
+    CXXFLAGS="$CXXFLAGS -fPIC -Wl,-z,relro,-z,now" \
+    LINKFLAGS="$LDFLAGS" \
+    $system_libs
+}
+
+package() {
+  cd $pkgname-$pkgver-stable
+  install -Dm644 misc/dist/linux/org.godotengine.Godot.desktop \
+    "$pkgdir/usr/share/applications/godot.desktop"
+  install -Dm644 icon.svg "$pkgdir/usr/share/pixmaps/godot.svg"
+  install -Dm755 bin/godot.x11.opt.tools.64 "$pkgdir/usr/bin/$pkgname"
+  install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/godot/LICENSE"
+  install -Dm644 misc/dist/linux/godot.6 "$pkgdir/usr/share/man/man6/godot.6"
+}