[arch-commits] Commit in hoogle/repos (2 files)

[Felix Yan]

    Date: Monday, December 13, 2021 @ 18:35:28
  Author: felixonmars
Revision: 1072065

archrelease: copy trunk to community-staging-x86_64

Added:
  hoogle/repos/community-staging-x86_64/
  hoogle/repos/community-staging-x86_64/PKGBUILD
    (from rev 1072064, hoogle/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: hoogle/repos/community-staging-x86_64/PKGBUILD (from rev 1072064, hoogle/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-12-13 18:35:28 UTC (rev 1072065)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=hoogle
+pkgver=5.0.18.2
+pkgrel=24
+pkgdesc="Haskell API Search"
+url="https://www.haskell.org/hoogle/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-quickcheck' 'haskell-aeson' 'haskell-blaze-html'
+         'haskell-blaze-markup' 'haskell-cmdargs' 'haskell-conduit' 'haskell-conduit-extra'
+         'haskell-connection' 'haskell-extra' 'haskell-foundation' 'haskell-hashable'
+         'haskell-http-conduit' 'haskell-http-types' 'haskell-js-flot' 'haskell-js-jquery'
+         'haskell-mmap' 'haskell-network' 'haskell-old-locale' 'haskell-process-extras'
+         'haskell-resourcet' 'haskell-src-exts' 'haskell-storable-tuple' 'haskell-tar'
+         'haskell-uniplate' 'haskell-utf8-string' 'haskell-vector' 'haskell-wai'
+         'haskell-wai-logger' 'haskell-warp' 'haskell-warp-tls' 'haskell-zlib')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('933564b12ffc95a89610e00fc8c7b35c90ce45a732a3812b58a9173c821dcec2e44a6625fa9b8b369706ea5d6e823c075ad3266664ed6649a057356d22f824df')
+
+build() {
+    cd $pkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --datasubdir="$pkgname" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+        --ghc-option='-pie'
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $pkgname-$pkgver
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}