[arch-commits] Commit in docker-scan/trunk (PKGBUILD)

[Morten Linderud]

    Date: Monday, December 13, 2021 @ 22:24:20
  Author: foxboron
Revision: 1072561

upgpkg: docker-scan 0.12.0-1

Added:
  docker-scan/trunk/PKGBUILD

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Added: PKGBUILD
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2021-12-13 22:24:20 UTC (rev 1072561)
@@ -0,0 +1,38 @@
+
+# Maintainer: Morten Linderud <foxboron at archlinux.org>
+
+pkgname=docker-scan
+pkgver=0.12.0
+pkgrel=1
+pkgdesc="Docker Scan is a Command Line Interface to run vulnerability detection on your Dockerfiles and Docker images"
+arch=('x86_64')
+url="https://github.com/docker/scan-cli-plugin"
+license=("Apache")
+makedepends=('go' 'git')
+_commit=1074dd0695bfef5cae2edccca2187e66ad400f8b	#refs/tags/v0.12.0
+source=("git+https://github.com/docker/scan-cli-plugin.git#commit=${_commit}")
+sha512sums=('SKIP')
+
+build() {
+  cd "scan-cli-plugin"
+  export CGO_CPPFLAGS="${CPPFLAGS}"
+  export CGO_CFLAGS="${CFLAGS}"
+  export CGO_CXXFLAGS="${CXXFLAGS}"
+  export CGO_LDFLAGS="${LDFLAGS}"
+  export GOFLAGS="-buildmode=pie -trimpath -modcacherw"
+  make -f builder.Makefile build
+}
+
+check(){
+  cd "scan-cli-plugin"
+  # mkdir cli-plugins
+  # cp bin/docker-scan_linux_amd64 cli-plugins/docker-scan
+  # export DOCKER_CONFIG="$(PWD)"
+  # go test ./...
+}
+
+package() {
+  cd "scan-cli-plugin"
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+  install -Dm755 bin/docker-scan_linux_amd64 "$pkgdir"/usr/lib/docker/cli-plugins/docker-scan
+}